XSL Attribute expression notation in text nodes - xslt

Question

value-of is horrible. When I need to insert a large number of variable values into a text node, it really pollutes the XSL file.
Is there a way to be able to use attribute expression notation, i.e. text text {$variable}, on the inside of an output text node? Or at least something more concise than value-of?

Answer 1

Not in XSLT 1.0. However, in XSLT 3.0 you can use TVTs (text value templates). They work the same as AVTs (attribute value templates).
To use a TVT, add the standard attribute xsl:expand-text="yes" to the element. This will cause the processor to treat descendant text nodes of that element as a TVT.
Example:
XSLT 3.0
<xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes"/>
<xsl:template match="/">
<xsl:variable name="who" select="'Dan'"/>
<xsl:variable name="what" select="'BAM!'"/>
<result xsl:expand-text="yes">This is {$who}'s result: {$what}</result>
</xsl:template>
</xsl:stylesheet>
Output (using any well-formed XML as input)
<result>This is Dan's result: BAM!</result>
Note: Tested using Saxon-PE 9.5.
Here's a better example showing the "descendant" text nodes being evaluated...
XML Input
<test>
<v1>one</v1>
<v2>two</v2>
<v3>three</v3>
</test>
XSLT 3.0
<xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
<xsl:template match="/*">
<result xsl:expand-text="yes">
<value>Value of v1: {v1}</value>
<value>Value of v2: {v2}</value>
<value>Value of v3: {v3}</value>
</result>
</xsl:template>
</xsl:stylesheet>
Output
<result>
<value>Value of v1: one</value>
<value>Value of v2: two</value>
<value>Value of v3: three</value>
</result>

Answer 2

You can use concat.
<xsl:value-of select="concat(
'text text ',
$variable,
'text text ',
$variable,
'text text'
)" />