XSLT 2.0 arithmetic when values can be NULL - xslt

Question

I'm using XSLT to transform a result set of numbers from a database into a nicely formatted table, including arithmetic to calculate totals.
The result set is being provided to me as an XML document (via SOAP) without any ability for me to alter the query that's used to generate it.
The problem: when the value should display as zero, this query returns a null/empty value into the XML result set. In order for the arithmetic to work, I need to convert these empty values, when they occur, into zero.
I've tried a variety of approaches, including a variable (see below) with no success - in this case, I get:
Cannot covert string "" to a double
I'm a bit limited in what I can do to pre-process the data: is there any way to achieve this with XSLT?
Input:
<DataResultSet xmlns="urn:...dataservice" xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:axis2ns531="urn:...dataservice">
<rows>
<row>
<A_PLAN>438</A_PLAN>
<A_ACTUAL>358</A_ACTUAL>
<B_PLAN />
<B_ACTUAL />
</row>
</rows>
</DataResultSet>
XSLT:
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0" xmlns:jdbc="urn:...dataservice" xmlns:xs="http://www.w3.org/2001/XMLSchema">
<xsl:output method="html"/>
<xsl:variable name = "A_PLAN" as="xs:double">
<xsl:choose>
<xsl:when test = "jdbc:A_PLAN = ''" ><xsl:text>0</xsl:text></xsl:when>
<xsl:otherwise><xsl:value-of select="jdbc:A_PLAN" /></xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="A_ACTUAL" as="xs:double">
<xsl:choose>
<xsl:when test = "jdbc:A_ACTUAL = ''" ><xsl:text>0</xsl:text></xsl:when>
<xsl:otherwise><xsl:value-of select="jdbc:A_ACTUAL" /></xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="B_PLAN" as="xs:double">
<xsl:choose>
<xsl:when test = "jdbc:B_PLAN = ''" ><xsl:text>0</xsl:text></xsl:when>
<xsl:otherwise><xsl:value-of select="jdbc:B_PLAN" /></xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="B_ACTUAL" as="xs:double">
<xsl:choose>
<xsl:when test = "jdbc:B_ACTUAL = ''" ><xsl:text>0</xsl:text></xsl:when>
<xsl:otherwise><xsl:value-of select="jdbc:B_ACTUAL" /></xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:template match="jdbc:row">|r|A|c|XXX|c|<xsl:value-of select="$A_PLAN"/>|c|<xsl:value-of select="$A_ACTUAL"/>|c|<xsl:value-of select="$A_ACTUAL - $A_PLAN"/>|r|B|c|XXX|c|<xsl:value-of select="$B_PLAN"/>|c|<xsl:value-of select="$B_ACTUAL"/>|c|<xsl:value-of select="$B_ACTUAL - $B_PLAN"/>|r|XXX|c|TTL|c|<xsl:value-of select="$A_PLAN + $B_PLAN"/>|c|<xsl:value-of select="$A_ACTUAL + $B_ACTUAL"/>|c|<xsl:value-of select="($A_ACTUAL - $A_PLAN) + ($B_ACTUAL - $B_PLAN)"/>
</xsl:template>
</xsl:stylesheet>

Answer 1

I would write
<xsl:variable name = "A_PLAN" as="xs:double">
<xsl:choose>
<xsl:when test = "jdbc:A_PLAN = ''" ><xsl:text>0</xsl:text></xsl:when>
<xsl:otherwise><xsl:value-of select="jdbc:A_PLAN" /></xsl:otherwise>
</xsl:choose>
</xsl:variable>
as
<xsl:variable name = "A_PLAN" as="xs:double"
select="if (//jdbc:A_PLAN castable as xs:double) then xs:double(//jdbc:A_PLAN) else 0"/>
So I have corrected the path to use //jdbc:A_PLAN as you seem to want to use global variables and then you need to search down in the document and I have used castable as to check the value.
Of course if you have several row elements using global variables does not make sense, I would then move the code into the template e.g.
<xsl:template match="jdbc:row">
<xsl:variable name = "A_PLAN" as="xs:double"
select="if (jdbc:A_PLAN castable as xs:double) then xs:double(jdbc:A_PLAN) else 0"/>