openmp gives different result from sequential - fortran

Question

I am a beginner with openmp. I am trying to parallize a simple loop. But its clearly wrong.
Can anyone kindly help?
use omp_lib
implicit none
integer ::n=20,it,j
real(8) :: a=0,b=5,s,func,del,sum1,tnm,x
it=2**(n-2)
tnm=it
del=(b-a)/tnm
x=a+.5*del
sum1=0.0
!$omp parallel do reduction(+:sum1)
do j=1,it
sum1=sum1+func(x)
! write(*,*)func(x)
x=x+del
end do
!$omp end parallel do
s=.5*(s+(b-a)*sum1/tnm)
write(*,*)s,sum1,it,del
end
function func(x)
real(8)::x
func=x
end function
EDIT
Results:
Parallel run::
$ ifort -openmp trapzd.f90
$ ./a.out
0.976562500000000 102400.000000000 262144
1.907348632812500E-005
Sequential Run
$ ifort trapzd.f90
$ ./a.out
6.25000000000000 655360.000000000 262144
1.907348632812500E-005
s,sum1 is different in this two run

Answer 1

I see three issues here:
A missing type declaration for the function func
s is used uninitialized
Race condition for variable x
This works for me:
program test
use omp_lib
implicit none
integer :: n=20,it,j
real(8) :: a=0,b=5,s,func,del,sum1,tnm,x,x0
it=2**(n-2)
tnm=it
del=(b-a)/tnm
x=a+.5*del
sum1=0.0
x0 = x
!$omp parallel do reduction(+:sum1)
do j=1,it
sum1=sum1+func(x0+j*del)
! write(*,*)func(x)
end do
!$omp end parallel do
! s is uninitialized here - set it to 0
! ...probably not what you had in mind
s = 0.
s=.5*(s+(b-a)*sum1/tnm)
write(*,*)s,sum1,it,del
end program
real(8) function func(x)
real(8)::x
func=x
end function
Compiled with gfortran:
OMP_NUM_THREADS=1 ./a.out
6.2500000000000000 655360.00000000000 262144 1.9073486328125000E-005
OMP_NUM_THREADS=6 ./a.out
6.2500000000000000 655360.00000000000 262144 1.9073486328125000E-005
Compiled with ifort:
OMP_NUM_THREADS=1 ./a.out
6.25000000000000 655360.000000000 262144 1.907348632812500E-005
OMP_NUM_THREADS=6 ./a.out
6.25000000000000 655360.000000000 262144 1.907348632812500E-005