SAS : how to test if a variable is numeric - sas

Question

I'm searching for a simple function to tell me if a given variable of a given dataset is numeric or not.
I would like to use it like this in an if statement in macro language:
%if isNumeric(ds,var) %then %do ...
But I can't find any way to achieve this simply. Do you have any idea if this is feasible?
I know it's probably trivial, but any help would be appreciated!
Thanks!

Answer 1

Assuming you want to know the actual type, and not the contents of a variable, there is a vartype(dsid,var-num) function which has the exact specifications you need, excepting it takes var-num not var-name. This example from the documentation should get you started; you can adapt this to use it to figure out a specific variable.
%let dsid=%sysfunc(open(mydata,i));
%let varlist=;
%do i=1 %to %sysfunc(attrn(&dsid,nvars));
%if (%sysfunc(vartype(&dsid,&i)) = N) %then
%let varlist=&varlist %sysfunc(varname
(&dsid,&i));
%end;
%let rc=%sysfunc(close(&dsid));

Answer 2

In Data Step using vtype function, we can also determine the type of a give variable from a dataset.
data _NULL_;
set sashelp.class (obs=1);
call symput('numvar',ifc(vtype(sex)='N','YES','NO' ));
run;
%put |&numvar|;
or, instead of call symput, we may use the following statement for elsewhere purposes.
if ifc(vtype(sex)='N','YES','NO' )='YES';

Answer 3

You recently edited your question so I thought I'd contribute with the following "simple function":
%if %mf_getvartype(sashelp.class,age)=N %then %put This var is numeric;
%if %mf_getvartype(sashelp.class,name)=C %then %put This var is character;
The mf_getvartype macro function is available in the SASjs core library here, and reproduced below:
/**
#file
#brief Returns variable type - Character (C) or Numeric (N)
#details
Usage:
data test;
length str $1. num 8.;
stop;
run;
%put %mf_getvartype(test,str);
%put %mf_getvartype(work.test,num);
#param libds Two part dataset (or view) reference.
#param var the variable name to be checked
#return output returns C or N depending on variable type. If variable
does not exist then a blank is returned and a note is written to the log.
#version 9.2
#author Allan Bowe
#copyright GNU GENERAL PUBLIC LICENSE v3
**/
%macro mf_getvartype(libds /* two level name */
, var /* variable name from which to return the type */
);
%local dsid vnum vtype rc;
/* Open dataset */
%let dsid = %sysfunc(open(&libds));
%if &dsid. > 0 %then %do;
/* Get variable number */
%let vnum = %sysfunc(varnum(&dsid, &var));
%if(&vnum. > 0) %then
/* Get variable type (C/N) */
%let vtype = %sysfunc(vartype(&dsid, &vnum.));
%else %do;
%put NOTE: Variable &var does not exist in &libds;
%let vtype = %str( );
%end;
%end;
%else %put dataset &libds not opened! (rc=&dsid);
/* Close dataset */
%let rc = %sysfunc(close(&dsid));
/* Return variable type */
&vtype
%mend;