I am trying to find a solution to do what `count neighbors with [any? turtles-here = true]' does, but instead of counting the black patches among the 8 neighboring patches to all patches that have the same y coordinate as the asking turtle.
Is there a way to implement a whole range of coordinates and ask for the number of patches with turtles within these coordinates?
You can definitely do this!
count patches with [ pycor = [ ycor ] of myself and any? turtles-here ]
myself refers to the agent that is doing the asking of other agents. In this case, it refers to the turtle that's counting the patches. Here, the turtle is asking the patches to execute the code in the reporter block. In order to get the ycor of the turtle in the context of the reporter block, you do [ ycor ] of myself.
Also, as an aside, note that the = true is unnecessary. any? turtles-here is already returning true or false, which is what you want the reporter block to return anyway!
Related
I'm creating clusters of agents using the nw extension weak-component-clusters.
It produces a list of agentsets.
My first goal is to calculate the average xcor and ycor of each of those agentsets in the list.
I can use map to count the number of agents in each agentset, but I can't map mean [xcor]
Example:
clear-all
create-turtles 5
ask turtle 0 [ create-link-with turtle 1 ]
ask turtle 0 [ create-link-with turtle 2 ]
ask turtle 3 [ create-link-with turtle 4 ]
let clusters nw:weak-component-clusters ; create list of agentsets
; output: [(agentset, 2 turtles) (agentset, 3 turtles)]
map count clusters ; Works
;output: [2 3]
map mean [xcor] clusters ; Does not work
;output: Expected a literal value
Secondary question: I will be calculating the distance between the clusters next and I was wondering if there was an extension or function that I could use instead of just using the distance between two points formula.
The problem is in the usage of your map function. As long as you are doing a very simple calculation (like for example your counting) map function list is sufficient. But when you want to calculate your mean xcor, you will need to add some anonymous procedure syntax.
map [ list-item -> function list-item ] list
In this case, you define a variable name that will be used for all the items of the list. This variable name is on the left of the ->. On the right side of the ->, you add a function utilising that variable. This function will then be applied to every item of the initial list, as you already know from map.
In your case, that gives us:
map [a-cluster -> mean [xcor] of a-cluster] clusters
Standard netlogo has a function for calculating the distance between agents (distance) and the distance between an agent and a point (distancexy) but no function for a distance between points. That said, the mathematical formula is simple so you could easily write your own function for that using to-report
How can I update the values in a list for the indices that are equal to everyone in the selected group agents?:
persons-own [
grouped
flockmates
]
to create-trustConnection
set nrPersons count persons
set vector []
repeat nrPersons [set vector 0.4 vector]
end
to updateVector
let alonePersons (count persons with [grouped = false])
set flockmates n-of (random alonePersons) persons
ask flockmates [
foreach vector [ i ->
set item i vector 0.6
]
]
end
You can use the replace-item reporter to update an item in a list.
Let this [ 1 2 3 4 ]
Let new-list replace-item 3 this “a”
Print new-list
Note that this does not affect the original list: it reports a new list with the specified item replaced with the given value.
Changing an item in a list of lists of similar.. but again, the entire list
Of lists is created anew.
But maybe use links?
In the case of using a list for a turtle to track its relationship with other turtles, or of groups, links are useful, and simplify managing those relationships, and enable things that are very difficult with lists.
LINKS are just another kind of agent, specifically for recording a relationship between two turtles. They have a pair of built-in variables, end1 and end2 that refer to those two turtles. The -own variables of the link can be used to record properties of the relationship. Like “anniversary” or “affinity” or whatever! Links can be directional, so the “intimacy” value can be different depending on the “direction” of the relationship.
Directed-link-breed [ relationships relationship]
Relationships-own [ intimacy ]
to setup-all-relationships
Ask protestors
[ setup-relationship ]
End
To setup-relationship
;; link with everyone else
Create-relationships-to other protestor
[ set intimacy .5 ]
End
The relationship between two turtles can be obtained in several ways.
(Link (this turtle) (that turtle))
Refers to the link from this turtle to that turtle.
Out-Link-neighbors is used to get the set of all turtles linked to from this turtle.
You can also use turtles to represent groups, and links to record membership in that group.
In that case, the members of the group are link-neighbors of the group.
While perhaps not a feature of your model, this opens up the possibility of multiple groups and of agents being members of more than one group, or of tracking things like former members.
Here is a complete, minimal reproducible example of what I think you are looking for. Note that one can just paste it into NetLogo and it compiles and runs. I've made some assumptions here - in particular that intimacy is a protesters-own variable, which it was not in the code you provided, but which your textual description seemed to indicate. Again, using who numbers is not a good idea, but that is a different question and answer. If I have time tomorrow, I might be able to provide you with an example of how one might use agentsets, but if intimacy values can vary from agent-pair to agent-pair, then links is really the way to go.
breed [protesters protester]
globals [numberOfProtesters intimacyVector]
protesters-own [
intimacy
partOfGroup ;initially set to false for all agents
myNRelatedProtesters
]
to setup
clear-all
create-protesters 10
create-intimacyRelationship
reset-ticks
end
to create-intimacyRelationship
ask protesters [
set numberOfProtesters count protesters
set intimacy []
repeat numberOfProtesters [set intimacy lput 0.2 intimacy]
set partOfGroup false
]
end
to updateIntimacy
let nrUngroupedProtesters (count protesters with [partOfGroup = false])
let NRelatedProtesters n-of (random nrUngroupedProtesters) protesters
ask NRelatedProtesters [
foreach ([who] of NRelatedProtesters) [ i -> set intimacy replace-item i intimacy 0.8 ]
set partOfGroup true
]
ask NRelatedProtesters [ show intimacy ]
end
to go
let ProportionProtestersInSubgroup (count protesters with [partOfGroup = true])/ numberOfProtesters
ifelse ((count protesters with [partOfGroup = false])/
numberOfProtesters) > ProportionProtestersInSubgroup
[
updateIntimacy
]
[
stop
]
tick
end
Hope this gets you started.
Hello NetLogo community,
I am trying to ask agents named "users" to save certain value (string) of a variable for last two ticks (last two instances when "Go" command is executed). But, users have to store these values after first two ticks. Can anyone suggest me a way out? I have tried implementing the following logic but it does not seem to work.
ask users
[
set history-length-TM 2
if ticks > 2
[
set TM-history n-values history-length-TM [mode-taken]
foreach TM-history [x = "car"]
[
commands that are to be executed
.....
......
]
]
]
"history-length-TM" is the extent of ticks for which the values are to be stored. "TM-History" is the list to store the values of variable "mode-taken". Please advise a better method that could help me achieve the intent. Thanks in advance.
I am not sure I completely understand how ticks relates to this question. My suggestion would be something along these lines:
globals [history-length-TM]
users-own [TM-history]
to setup
set history-length-TM 2
...
end
ask users
....
set TM-history fput mode-taken TM-history
if length [TM-history] > history-length-TM [set TM-history but-last TM-history]
end
The idea is that the memory fills up (using fput) by placing the new mode-taken at the front of the list. Once the memory is too long, then the last (which is oldest) is dropped off the list.
I have a problem with a NetLogo-list (V. 6.0.2) and the member? command, somehow not doing what I want it to do.
Each turtle builds its list "aware-of-who":
ask turtles [
foreach cheater-list [ x ->
if random-float 100 < 90
[set aware-of-who lput ([who] of x ) aware-of-who]
]
It builds the lists of who-numbers successfully for the turtles.
Then I ask turtles to look for those neighbors, that have their who-number in their "aware-of-who" list (i.a. are "aware of them"), with this code:
let punishers (turtles-on neighbors) with
[ member? ([who] of myself) ( [aware-of-who] of self) = true]
It does not seem to report true, even if from all I can tell it should (the respective who numbers do appear in their lists). The code also does report true if I ask for (turtles-on neighbors) with [ empty? aware-of-who = false].
Any ideas what's wrong here?
Thanx!!
It seems like a case of mixing up self and myself. In the following code:
let punishers (turtles-on neighbors) with
[ member? ([who] of myself) ( [aware-of-who] of self) = true]
The code between the square brackets is passed to the with reporter and runs in the context of the calling turtle's neighbors. So within the reporter, self is the neighbor and myself is the calling turtle. You have it the other way around.
That being said... don't do it this way! And by this, I mean: don't use lists of who numbers. It is almost never necessary to use who numbers in NetLogo. Whenever you think you need who numbers for something, come ask a question here: someone will most likely show you a better way to do it.
The way around who numbers is usually to store references to turtles directly, either in a list or an agentset. It seems like you already know how that works, since cheater-list is apparently a list of turtles.
To construct you list of cheaters that a turtle is aware of, you could just use filter:
let known-cheaters filter [ random-float 100 < 90 ] cheaters
Finding your punishers then becomes a bit nicer:
let punishers (turtles-on neighbors) with [
member? self [ known-cheaters ] of myself
]
Also note that you should almost never write = true or = false. If something is true or false, you can use it directly in an expression (with a not in front if you're interested in the case where it's false). For example, you can write:
turtles with [ not member? self cheaters ]
instead of:
turtles with [ member? self cheaters = false ]
I have to do some operations in netlogo using Lists. While i can do simple tasks with them i am not yet proficient enough to code my current requirements.
I have a scenario where turtles have variables called Current-Age and Previous-Age. And turtles can be born and die if they don't meet a certain threshold.
I want to implement the following formula for each patch.
Best-list = (-1/Previous-Age) * (Distance between Patch & Turtle) for all the turtles
Best = Min [ Best-list]
I know the steps involved but have been unsuccessful in coding them. Following are the steps:
Create a list with all the current turtles that are alive
Create a second list which contains the Previous-Age
Create a third list with the distance between an individual patch and each of the live turtles
Then create another list with the output from the the Best-List formula for all the turtles in the list
Finally find the Min value in the list and store the name/who# of turtle with the minimum value in a separate variable called Best-Turtle
This is the code that i tried but didn't work.
set turtle-list (list turtles)
set turtle-age-list n-values length(turtle-list) [0]
set turtle-patch-dist-list n-values length(turtle-list) [0]
set best-list n-values length(turtle-list) [0]
ask patches[
foreach turtle-list(
set turtle-age-list replace-item ?1 turtle-age-list Previous-Age of turtles with [turtle= ?1]
)
]
I couldn't proceed to the next steps since the above code itself was not correct.
Would appreciate help with the code, thanks in advance.
Regards
First, lists are probably not the simplest way to do this. However, if you must use lists for some reason, I think what you're asking for is possible. I'm not exactly sure what you mean with best- are you trying to have each patch assess which turtle is the best turtle for that patch, and store that variable in a global list? I'm going to assume that's what you mean, but if I'm misunderstanding I think you can adapt what I do here to what you need.
First, any list passed to foreach must be the same length. So, since you mean to do this per-patch, make sure that every patch calls the procedure of list creation, not just for checking the lists. Next, review the dictionary for n-values- the syntax for the reporter means you need to use the reporter you're trying to receive- using n-values length(turtle-list) [0] will just give you a list of zeroes that is the same length as the number of turtles.
So each patch needs to create these lists- make sure you either define the patches-own for the list variables, or just use let to define the lists inside the procedure. You would need a list of ordered turtles, their previous ages, and the distance from the patch calling the procedure to each turtle. Next, you can create a list that generates a value according to your formula. Then, you can use the position primitive to find the location of the minimum value in your formula-generated list and use that to index the turtle with that value.
It might look something like
to numerical
set best-turtle []
ask patches [
let turtle-list (sort turtles) ;;; list of sorted turtles
let turtle-prev-age-list n-values length(turtle-list) [ [i] -> [pre_age] of turtle i ] ;;; list of previous ages of turtles, in same order as above
let turtle-patch-dist n-values length(turtle-list) [ [i] -> distance turtle i ] ;;; list of distance from this patch to each turtle, in same order
set best-list n-values length(turtle-list) [ [i] -> ( ( -1 / ( item i turtle-prev-age-list ) ) * ( item i turtle-patch-dist ) ) ] ;;; list of calculated values for each turtle
let best-position position (min best-list) best-list ;;; gets the index of minimum value
set best-turtle lput item best-position turtle-list best-turtle ;;; adds the best turtle for this patch to the global list of best turtles
]
end
The above procedure assumes that your turtles have a pre_age variable, patches have a best-list variable, and the list of each patches 'best turtle' is held in the global variable best-turtle. From there, you can use foreach to ask turtles in the list to do something. Note that if a turtle's previous age is 0, you will get a divide by zero error.
turtles-own [age previous-age]
to-report evalfrom [_patch]
report (- distance _patch) / previous-age
end
to test
ca
crt 25 [
set age (10 + random 75)
set previous-age age - random 10
]
print min-one-of turtles [evalfrom (patch 0 0)]
end