Check whether xpath value is contained in a list - xslt

Question

I have to set a variable value in XSLT based on whether the value in an xpath is one among a list of values. Is there any way other than doing
<xsl:variable name="isBuyable">
<xsl:choose>
<xsl:when test="$someVar='A'">
<xsl:value-of select="true()"/>
</xsl:when>
<xsl:when test="$someVar='B'">
<xsl:value-of select="true()"/>
</xsl:when>
<xsl:when test="$someVar='C'">
<xsl:value-of select="true()"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="false()"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
or like
<xsl:variable name="isBuyable">
<xsl:choose>
<xsl:when test="$someVar='A' or $someVar='B' or $someVar='C'">
<xsl:value-of select="true()"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="false()"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
someVar holds the value in an xpath.
Is it possible to do something like <xsl:when test="contains($listVar, $someVar)>" where listVar is a variable holding the list of required values?

Answer 1

In XSLT 2.0 you can have sequences of atomic values, so you can do
<xsl:variable name="isBuyable" select="$someVar = ('A', 'B', 'C')" />
In 1.0 you only have node sets, not atomic sequences, so it's a bit more fiddly. If your processor supports a node-set extension function (the msxsl one for Microsoft processors, exslt for most others) then you can do
<xsl:variable name="buyableValuesRTF">
<val>A</val>
<val>B</val>
<!-- etc -->
</xsl:variable>
<xsl:variable name="buyableValues" select="exslt:node-set($buyableValuesRTF)/val"/>
to create a node set with the valid values, which you can then compare against:
<xsl:variable name="isBuyable" select="$someVar = $buyableValues"/>
In both versions this works because an = comparison where one argument (or both) is a sequence succeeds if any of the elements on the left matches any of the ones on the right.
To do it in 1.0 without an extension function you'll have to fake the sequence using substring matching - define the list of allowed values as a string delimited by some character that is not in any of the values
<xsl:variable name="buyableValues" select="'|A|B|C|'"/>
and use the contains function to check for a substring:
<xsl:variable name="isBuyable" select="contains($buyableValues,
concat('|', $someVar, '|'))"/>