Find the first number in a string, could be 1,11,111 - regex

Question

I am looping through file names with such pattern name_name-number-name_name.txt
I need to extract the number.
For example,
from xxx_xx-111-ssadas22 I would get 111.
from xxx_xx-11-sadaesdwsq4443fsd2 I would get 11
Currently using this but it falls short when there is a number in the name. Also tried a regex but am bad at it.
Function FirstDigit(strData As String) As Integer
Dim RE As Object
Dim REMatches As Object
Set RE = CreateObject("vbscript.regexp")
With RE
.Pattern = "(^|\\s)([0-100]+)($|\\s)"
End With
Set REMatches = RE.Execute(strData)
FirstDigit = REMatches.item(0)
End Function
any idea ?

Answer 1

Try This:
Function FirstDigit(strData As String) As Integer
Dim RE As Object
Dim REMatches As Object
Set RE = CreateObject("vbscript.regexp")
With RE
.Pattern = "\b[^_\s]+_[^-\s]+-(\d+)-[^\.\s]+\.txt\b"
End With
Set REMatches = RE.Execute(strData)
If REMatches.Count > 0 Then
FirstDigit = REMatches(0).SubMatches(0)
Else
FirstDigit = -1 '' or whatever you want to output when there is no match
End If
End Function
Test:
Sub Test()
Debug.Print FirstDigit("xxx_xx-1-ssadas22.txt") '' Returns 1
Debug.Print FirstDigit("xxx_xx-11-ssadas22.txt") '' Returns 11
Debug.Print FirstDigit("xxx_xx-111-ssadas22.txt") '' Returns 111
Debug.Print FirstDigit("xxx_xx-asasa-ssadas22.txt") '' Returns -1 (no match)
End Sub

Answer 2

How about:
Function FirstDigit(strData As String) As Integer
FirstDigit = 0
ary = Split(strData, "-")
For i = LBound(ary) To UBound(ary)
If IsNumeric(ary(i)) Then
FirstDigit = CInt(ary(i))
Exit Function
End If
Next i
End Function

Answer 3

If the pattern of the string remains the same then this works for me
Sub Sample()
Debug.Print FirstDigit("xxx_xx-1-ssadas22")
Debug.Print FirstDigit("xxx_xx-11-ssadas22")
Debug.Print FirstDigit("xxx_xx-111-ssadas22")
End Sub
Function FirstDigit(strData As String) As Integer
Dim RE As Object
Dim REMatches As Object
Set RE = CreateObject("vbscript.regexp")
With RE
.Pattern = "(\-([^-]+)\-)"
End With
Set REMatches = RE.Execute(strData)
FirstDigit = Abs(Val(REMatches.Item(0)))
End Function

Answer 4

This works, and doesn't require your filenames to fit any particular pattern. For any input string it will return the first (whole) number i.e. the first sequence of consecutive digit characters.
Function GetFirstNumber(s As String) As String
Dim i As Long
Dim strFirstNumber As String
Dim thisChar As String
Dim foundNumberStart As Boolean
For i = 1 To Len(s)
thisChar = Mid(s, i, 1)
If thisChar Like "[0-9]" Then
foundNumberStart = True
strFirstNumber = strFirstNumber & thisChar
ElseIf foundNumberStart Then
Exit For 'Number finished.
End If
Next i
GetFirstNumber = strFirstNumber
End Function
Example usage:
?GetFirstNumber(" xxx_xx-111-ssadas22")
111
?GetFirstNumber("xxx_xx-11-sadaesdwsq4443fsd2")
11
?GetFirstNumber(" kjhsdfg WWWAAHHH!*666zombiesarecoming9827365498#%")
666