only text value of element through xslt - xslt

Question

I have a below XML. I want to get the text value of Title element. I have used <xsl:value-of select="Title/text()"/>,But it does not fetch the output.
XML-
<Section>
<Chapter>
<Title>
<Marker>MarkerText1</Marker>some text1
</Title>
</Chapter>
<Chapter>
<Title>
<Marker>MarkerText2</Marker>sometext2
<Marker>MarkerText3</Marker>some text3
</Title>
</Chapter>
</Section>
I have used below XSL but it does not fetch any results. And when I used Title/text()[last()] then it gives the last value. I mean text()[last()] is working but not just text()
<xsl:template match="/Section/Chapter">
<xsl:value-of select="Title/text()"/>
</xsl:template>
Output should contain:
<Title>some text1</Title><Title>some text2 sometext3</Title>

Answer 1

If you're using XSLT 1.0, then the value-of a node set is the string value of its first node in document order. So
<xsl:value-of select="Title/text()"/>
will give you the value of the first child text node under the first (in this case only) Title element under the current context node. For the Chapter elements in your example this would be the text node between the opening <Title> tag and the opening <Marker> tag, which consists of a single newline character.
XSLT 2.0 is different, in that case value-of would give you the values of all the selected nodes, separated by spaces, for the first Chapter this would be newline, space, some text1, newline.

Answer 2

I'm not sure what you mean by the "text value", but if you mean the same as what the spec calls the "string value", then use
<xsl:value-of select="Title"/>
If that's not what you want then you need to explain your desired output more clearly.

Answer 3

This XML input:
<?xml version="1.0" encoding="utf-8"?>
<Section>
<Chapter>
<Title>
<Marker>MarkerText1</Marker>some text1
</Title>
</Chapter>
<Chapter>
<Title>
<Marker>MarkerText2</Marker>some text2
<Marker>MarkerText3</Marker>some text3
</Title>
</Chapter>
</Section>
Provided to this XSLT transformation:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="/">
<Titles>
<xsl:apply-templates/>
</Titles>
</xsl:template>
<xsl:template match="Title">
<Title><xsl:apply-templates select="text()"/></Title>
</xsl:template>
<xsl:template match="Title/text()">
<xsl:copy/>
</xsl:template>
</xsl:stylesheet>
Yields this XML output:
<?xml version="1.0" encoding="UTF-8"?>
<Titles>
<Title>some text1
</Title>
<Title>some text2
some text3
</Title>
</Titles>
Explanation:
The match="/" template establishes a root element for the produced
Title elements. (The rootless sequence of Title elements you mention in
your question would not be well-formed XML.)
The match="Title" template generates the requested Title elements
and applies pattern matching on the contained text() nodes.
The match="Title/text() template copies over text nodes that are
children of Title elements in the input XML.
If you'd prefer your output to look like this:
<?xml version="1.0" encoding="utf-8"?>
<Titles>
<Title>some text1</Title>
<Title>some text2 some text3</Title>
</Titles>
You can use this slightly more complicated template for match="Title/text()":
<xsl:template match="Title/text()">
<xsl:if test="preceding-sibling::text()">
<xsl:text> </xsl:text>
</xsl:if>
<xsl:value-of select="normalize-space()"/>
</xsl:template>