Perl regular expression unintendedly seems to be modifying a source String - regex

Question

Am trying to match some data patterns from a file in a Perl program. Since the match could be over multiple lines, I have made the line seperator as undefined.
$/ = undef ;
Now, since the match can be across multiple lines and more than one, I am using smgi modifiers.
if ( $msgText =~ /$msgTypeExpr/smgi )
Now, the problem I am having is that the variable $msgText above gets modified though I am not replacing it.
Here is the relevant code:
open (HANDLE1,"$file") || die "cannot open file \n";
$/ = undef ;
while ( my $msgText = <HANDLE1> )
{
my $msgTypeExpr = "<city\\W+";
print "Attempt 1:\n";
if ( $msgText =~ /$msgTypeExpr/smgi )
{
print "matched\n";
}
else
{
print " not matched \n";
}
print "Attempt 2:\n";
if ( $msgText =~ /$msgTypeExpr/smgi )
{
print "matched\n";
}
else
{
print " not matched \n";
}
}
The test input file looks like this:
<city
name="abc">
</city>
One would expect the pattern to match twice but it is matching the first time only and not the second time around.
I have temporarily fixed this issue with assigning to a temp variable for now before matching and using that temp variable to match.
my $tmpMsgText = $msgText ;
This is the first time I am posting a question on this forum, so please pardon any etiquettes mistakes I may have made and also please be kind enough to point them out so that I don't repeat in the future.

Answer 1

if (//g) makes no sense. "If it matches and keeps on matching until there's no match"? Get rid of the g.
I don't know why you're using s or m either.
The s is useless since the pattern doesn't contain ..
The m is useless since the pattern doesn't contain ^ or $.
In reality, //g in scalar context acts as an iterator.
$ perl -E'$_ = "abc"; /(.)/g && say $1; /(.)/g && say $1;'
a
b

Answer 2

first of all, I'm not sure about reading a file like that. Modifying those Perl-special variables, like $/ should be done with local, like this:
local $/ = undef;
this way the variable is only modified in the current scope (thus eliminating possible action-in-the-distance bugs). By setting $/ to undef you will read the entire file in one go, so there is no point putting a while loop there. I'd read the whole file like this:
open my $fh, "<", "somefile" or die;
my $content = do { local $/ = undef; <$fh> };
the do block restricts the modified $/ value only to that one statement (it creates a new scope).
About regex matching: remove the /g modifier after the regex. If I remember correctly, it will remember the last regex search position and continue from there. Also for detecting if a string was altered or not, print the variable before and after those matches. You will see, that they are not modified.
Instead of:
if ( $msgText =~ /$msgTypeExpr/smgi )
put:
if ( $msgText =~ /$msgTypeExpr/smi )