Using xsl:value-of in xsl:template 's - xslt

Question

I am passing an xml file to my fo file which looks like:
<?xml version="1.0"?>
<activityExport>
<resourceKey>
<key>monthName</key>
<value>January</value>
</resourceKey>
So if I directly use:
<xsl:value-of select="activityExport/resourceKey[key='monthName']/value"/>
I can see "January" in my PDF file just fine.
However, if I use it like this in a template I have:
<xsl:template name="format-month">
<xsl:param name="date"/>
<xsl:param name="month" select="format-number(substring($date,6,2), '##')"/>
<xsl:param name="format" select="'m'"/>
<xsl:param name="month-word">
<xsl:choose>
<xsl:when test="$month = 1"><xsl:value-of select="activityExport/resourceKey[key='monthName']/value"/>
</xsl:when>
Then I do not see "January" when I call:
<xsl:variable name="monthName">
<xsl:call-template name="format-month">
<xsl:with-param name="format" select="'M'"/>
<xsl:with-param name="month" select="#monthValue"/>
</xsl:call-template>
</xsl:variable>
<xsl:value-of select="concat($monthName,' ',#yearValue)"/>
I know my template works because if I have a static string in:
<xsl:choose>
<xsl:when test="$month = 1">Januaryyy</xsl:when>
Then I can see Januaryyyy fine.
So the template works, the resource exists, but the value-of-select does not work inside of call-template or xsl:choose or xsl:when test
Any help?
Regards!

Answer 1

Your template is probably fine, except that you are calling it from an unsuitable position in your XML. Therefore, the XPath you are using to set month-word does not find anything - it is a path to nothing.
For example, the following XSLT stylesheet:
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:template match="#* | node()">
<xsl:copy>
<xsl:apply-templates select="#* | node()"/>
</xsl:copy>
</xsl:template>
<xsl:template name="format-month">
<xsl:param name="date"/>
<xsl:param name="month" select="format-number(substring($date,6,2), '##')"/>
<xsl:param name="format" select="'m'"/>
<xsl:param name="month-word">
<xsl:choose>
<xsl:when test="$month = 1">
<xsl:value-of select="activityExport/resourceKey[key='monthName']/value"/>
</xsl:when>
</xsl:choose>
</xsl:param>
<xsl:value-of select="$month-word"/>
</xsl:template>
<xsl:template match="/">
<xsl:variable name="monthName">
<xsl:call-template name="format-month">
<xsl:with-param name="month" select=" '1' "/>
<xsl:with-param name="format" select="'M'"/>
</xsl:call-template>
</xsl:variable>
<xsl:value-of select="concat($monthName,' ',#yearValue)"/>
</xsl:template>
</xsl:stylesheet>
applied to this XML:
<activityExport>
<resourceKey>
<key>monthName</key>
<value>January</value>
</resourceKey>
</activityExport>
produces this output:
January
Note that I have replaced the month parameter to your template with the value 1. No elements in this input XML have a #monthValue attribute (which is what lead me to believe you are calling the template from an unsuitable location) and so month-word would not get set either because of the xsl:choose.
To make things work with your real input XML, you could try replacing the XPath with "//activityExport/resourceKey[key='monthName']/value" where the double-slash defines a path to anywhere within the XML document. This should be fine if there is only one activityExport node. Otherwise, you will need to work out the suitable XPath.