BATCH - RPS - Rock, Paper, Scissors - Keep failing after a few rounds - if-statement

Question

I have been trying to make a rock, paper, scissors game in batch. So far, the script runs and I can make it play against itself or to play against me (I need to change the B var from /A and random number to /P and have user input).
The thing is that after a few (different amount every time) rounds, the script crash and I do not have time to read the last line of text (which would help me find the error). I have tried with ECHO ON and OFF, I also tried to run 'RPS.bat >> log.txt' from a different DOS window (with the right directory chosen). That did log everything until it crashed, and did not get the last line either.
I have been looking through it several times, but I cant find the error... :(
I made the same game in PHP with currently no errors... (it is a totally different language, I know)
So here is my script:
#ECHO OFF
:TOP
SET /A AWON=0
SET /A BWON=0
SET /A NWON=0
:GAME
SET /A A=%RANDOM% %% 3 + 1
SET /P B=Number from 1 to 3
IF %A% EQU 1 (
GOTO A1
) ELSE IF %A% EQU 2 (
GOTO A2
) ELSE IF %A% EQU 3 (
GOTO A3
) ELSE (
GOTO GAME
)
:A1
IF %B% EQU 1 (
GOTO DRAW
) ELSE IF %B% EQU 2 (
GOTO BWIN
) ELSE IF %B% EQU 3 (
GOTO AWIN
) ELSE (
GOTO GAME
)
:A2
IF %B% EQU 1 (
GOTO ARAW
) ELSE IF %B% EQU 2 (
GOTO DRAW
) ELSE IF %B% EQU 3 (
GOTO BWIN
) ELSE (
GOTO GAME
)
:A3
IF %B% EQU 1 (
GOTO BWIN
) ELSE IF %B% EQU 2 (
GOTO AWIN
) ELSE IF %B% EQU 3 (
GOTO DRAW
) ELSE (
GOTO GAME
)
:AWIN
SET /A AWON=%AWON% + 1
ECHO -------------------------------------------------------------------------------
ECHO A won this round!
ECHO ---
ECHO A won: %AWON%
ECHO B won: %BWON%
ECHO Draw: %NWON%
PAUSE
GOTO GAME
:BWIN
SET /A BWON=%BWON% + 1
ECHO -------------------------------------------------------------------------------
ECHO B won this round!
ECHO ---
ECHO A won: %AWON%
ECHO B won: %BWON%
ECHO Draw: %NWON%
PAUSE
GOTO GAME
:DRAW
SET /A NWON=%NWON% + 1
ECHO -------------------------------------------------------------------------------
ECHO This round was a draw!
ECHO ---
ECHO A won: %AWON%
ECHO B won: %BWON%
ECHO Draw: %NWON%
PAUSE
GOTO GAME
Thanks to Gray for helping me out with my stupid mistake ^^
Also thanks for the script, but if I am not missing something here, it is not quite correct.
#ECHO OFF
:GAME
SET /P A=A:
SET /P B=B:
SET /A WINNER=(%A%-%B%) %% 3
ECHO %A% - %B% = %WINNER%
IF %WINNER% EQU 1 (
echo A WON!
) ELSE (
IF %WINNER% EQU 0 (
echo DRAW!
) ELSE (
echo B WON!
))
PAUSE
GOTO GAME
Run that script (a 'shortened' version of Gray's script). Use the variables like as in my 'table', you can see that by choosing 1 (rock), A is not able to win (A=1 vs B=3 should be: A WON). Do you have any idea on how to fix this? I guess a 'hard-coded?' solution when A=1 and B=3 would be best? (I mean that when those are the values, the 'normal' script does not apply, but a special code gives the result instead).
In my table, if the last sign is '+', then the script gives the correct answer, if the last sign is a '-', then the script gives an incorrect answer.
ITEM VALUE
ROCK 1
PAPER 2
SCISSORS 3
A - B = WINNER
1 - 1 = 0 DRAW +
1 - 2 = -1 B WON +
1 - 3 = -2 A WON -
2 - 1 = 1 A WON +
2 - 2 = 0 DRAW +
2 - 3 = -1 B WON +
3 - 1 = 2 B WON +
3 - 2 = 1 A WON +
3 - 3 = 0 DRAW +
Also, if you have any tips on how to keep the script more tidy and use less lines code to do the same job, I would gladly listen!
Thanks in advance! - Espen

Answer 1

Your error likely says:
The system cannot find the batch label specified - ARAW
This is because you have GOTO ARAW in your A2 label, when it looks like you meant to do GOTO AWIN
Bonus: as a more "clever" way of determining the winner (can surely be improved more)
#echo off
rem rock:1; paper:2; scissors:3
:GAME
SET /A CPU=%RANDOM% %% 3 + 1
SET /P PLAYER=Number from 1 to 3
cls
echo %CPU% vs %PLAYER%
rem set /A WINNER=(%CPU%-%PLAYER%) %% 3 //this does not work with batch - my mistake
SET /A WINNER=(%CPU% - %PLAYER% + 3) %% 3
IF %WINNER% EQU 1 (
echo CPU WON!
) ELSE (
IF %WINNER% EQU 0 (
echo DRAW!
) ELSE (
echo YOU WON!
))
GOTO GAME
And finally, here is one that prints "rock", "paper", and "scissors" to make it a little more... fun
#echo off
rem rock:1; paper:2; scissors:3
:GAME
SET /A CPU=%RANDOM% %% 3 + 1
SET /P PLAYER=Number from 1 to 3
goto CPUTYPE
:TYPE1
goto PLAYERTYPE
:TYPE2
cls
echo CPU:%CPUT% vs YOU:%PLAYERT%
rem set /A WINNER=(%CPU%-%PLAYER%) %% 3 //this does not work with batch - my mistake
SET /A WINNER=(%CPU% - %PLAYER% + 3) %% 3
IF %WINNER% EQU 1 (
echo CPU WON!
) ELSE (
IF %WINNER% EQU 0 (
echo DRAW!
) ELSE (
echo YOU WON!
))
GOTO GAME
:CPUTYPE
IF %CPU% EQU 1 (
SET CPUT="ROCK"
) ELSE (
IF %CPU% EQU 2 (
SET CPUT="PAPER"
) ELSE (
SET CPUT="SCISSORS"
))
GOTO TYPE1
:PLAYERTYPE
IF %PLAYER% EQU 1 (
SET PLAYERT="ROCK"
) ELSE (
IF %PLAYER% EQU 2 (
SET PLAYERT="PAPER"
) ELSE (
SET PLAYERT="SCISSORS"
))
GOTO TYPE2
Updated version based on asker's PvP version (fixed modul
#ECHO OFF
:GAME
SET /P A=A:
SET /P B=B:
SET /A WINNER=(%A% - %B% + 3) %% 3
ECHO W= %WINNER%
IF %WINNER% EQU 1 (
echo A WON!
) ELSE (
IF %WINNER% EQU 0 (
echo DRAW!
) ELSE (
echo B WON!
))
PAUSE
GOTO GAME
Explanation of SET /A WINNER=(%CPU% - %PLAYER% + 3) %% 3:
2 beats 1, 3 beats 2, and 1 beats 3. If you draw it out, it is kind of circular. We use the % or modulus operator to do that. The modulus operator basically gives you the remainder if you had divided by that number using integer division.
Here are 1 through 6 mod 3, with the answer in bold.
1 / 3 = 0 rem 1
2 / 3 = 0 rem 2
3 / 3 = 1 rem 0
4 / 3 = 1 rem 1
5 / 3 = 1 rem 2
6 / 3 = 2 rem 0
Notice how the result is always < 3 and > 0? We exploit this mechanic to mimic the circular behavior of rock paper scissors. You also may have noticed I didn't do the +3 in those examples. The +3 was added because the way Microsoft chose to implement modulus, it does weird things when you have a negative number (that was how we fixed the bug you caught). I had assumed it used a modulus like I was used to where the sign didn't change the outcome. Basically, it just shifts the operation up 3 so that it is never negative. You can read more about this kind of thing here: circular buffer. I like examples, so here is something that may help.
Ties:
1v1 -> (1 - 1 + 3) % 3 -> 3 % 3 -> 1 rem 0
2v2 -> (2 - 2 + 3) % 3 -> 3 % 3 -> 1 rem 0
3v3 -> (3 - 3 + 3) % 3 -> 3 % 3 -> 1 rem 0
player 1 win
1v3 -> (1 - 3 + 3) % 3 -> 1 % 3 -> 0 rem 1
2v1 -> (2 - 1 + 3) % 3 -> 4 % 3 -> 1 rem 1
3v2 -> (3 - 2 + 3) % 3 -> 4 % 3 -> 1 rem 1
player 2 win
1v2 -> (1 - 2 + 3) % 3 -> 2 % 3 -> 0 rem 2
2v3 -> (2 - 3 + 3) % 3 -> 2 % 3 -> 0 rem 2
3v1 -> (3 - 1 + 3) % 3 -> 5 % 3 -> 1 rem 2
The pattern here is that all of the remainders (results of the modulus operator) all match up. How convenient! Now we can just match that case to an if-statement, and we know who won every game.