TCL :I am getting the following error while creating fibonacci - list

Question

proc Fibonacci {x} {
set n(0) 0; set n(1) 1
set i 2
while {$i <= $x} {
set n($i) [expr n($i-2) + n($i-1)]
incr i
}
return $n($i)
}
set y [Fibonacci 10]
puts "$y"
I am getting the below error while compliling the above program. please correct me

Answer 1

Your problem is twofold in this statement:
set n($i) [expr n($i-2) + n($i-1)]
First of all, you have to get the value of n($i-2), not it's name, so you should change it to this:
set n($i) [expr {$n($i-2) + $n($i-1)}]
I also introduced {} to make expr a bit tidier and less error-prone. However, that still won't work, because $i-2 will not be calculated before trying to index the n array, so you need this:
set n($i) [expr {$n([expr {$i-2}]) + $n([expr {$i-1}])}]
Fixed? Nope, this line is still wrong:
return $n($i)
You see, you index by $i, but in your loop, you write to n($i) and after that immediately increase i, so it will be one higher than the last element. You need to change it to this:
return $n($x)
This gives a working version with your code:
proc Fibonacci {x} {
set n(0) 0
set n(1) 1
set i 2
while {$i <= $x} {
set n($i) [expr {$n([expr {$i-2}]) + $n([expr {$i-1}])}]
incr i
}
return $n($x)
}
set y [Fibonacci 10]
puts "$y"
This can still be done bether however, let's use for instead of while:
proc Fibonacci1 {x} {
set n(0) 0
set n(1) 1
for {set i 2} {$i <= $x} {incr i} {
set n($i) [expr {$n([expr {$i-2}]) + $n([expr {$i-1}])}]
}
return $n($x)
}
And let's replace that array by a list, which semantics work much better here:
proc Fibonacci2 {x} {
set n [list 0 1]
for {set i 2} {$i <= $x} {incr i} {
lappend n [expr {[lindex $n end] + [lindex $n end-1]}]
}
return [lindex $n end]
}
Arrays are quite useless here as they are actually associative containers in tcl, a list is a sequential container, what you obviously use in this algorithm. You can see this in speed, this was what I got on my computer with tcl 8.6:
time {Fibonacci1 100} 10000
64.1805 microseconds per iteration
time {Fibonacci2 100} 10000
23.9295 microseconds per iteration

Answer 2

Here is a working solution based on your code:
proc Fibonacci {x} {
set n(0) 0; set n(1) 1
set i 2
while {$i <= $x} {
set fiboMinus1 $n([expr {$i - 1}])
set fiboMinus2 $n([expr {$i - 2}])
set n($i) [expr {$fiboMinus1 + $fiboMinus2}]
incr i
}
return $n($x)
}
set y [Fibonacci 10]
puts "$y"