Generate each TR with 3 TD's in XSL (The Right Way)? - xslt

Question

I simply need to have 3 products in each row. Each Product is in the template "OneProduct" (not included) and, the putter most Table tags are outside this table.. The following actually does work but, how is it done the right way?
<xsl:if test="(position() mod 3) = 1">
<xsl:text disable-output-escaping="yes">
<![CDATA[<TR name="PROD_ROW">]]>
</xsl:text>
</xsl:if>
<TD width="33%" align="center" name="PRODUCT_CELL">
<xsl:call-template name="OneProduct">
<xsl:with-param name="productId" select="$productId" />
</xsl:call-template>
</TD>
<xsl:if test="( (position()+1) mod 3 = 1)">
<xsl:text disable-output-escaping="yes">
<![CDATA[</TR>]]>
</xsl:text>
</xsl:if>

Answer 1

In answer to your question, that is not the preferred way. It is the sort of thing you may do in a procedural language; iterate over the elements incrementing a counter and then outputting the delimiting elements when you reach the 3rd, 6th, etc, elements. But XSLT is a functional language, and a different approach is needed.
What you could do is use xsl:apply-templates to select the elements that will be first in each row. Assuming you had some XML like this
<products>
<product id="1" name="Product 1" />
<product id="2" name="Product 2" />
<product id="3" name="Product 3" />
<product id="4" name="Product 4" />
<product id="5" name="Product 5" />
</products>
Then your xsl:apply-templates would be like this:
<xsl:apply-templates select="product[position() mod 3 = 1]" />
Within the template that matched the product element, you would then select all the elements in the row (i.e. the current element, plus the two following elements)
<xsl:apply-templates
select="self::*|following-sibling::product[position() < 3]" mode="cell" />
Note the use of mode here, as you will have two templates matching product and you need to distinguish between them.
Finally, you would just have this 'cell' template to output the product.
<xsl:template match="product" mode="cell">
<td>
<xsl:value-of select="#name" />
</td>
</xsl:template>
The only thing to worry about would be if you didn't have an exact number of cells for each row (for example, in this example there are five products, so the last row only has two cells.
Try the following XSLT
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html" />
<xsl:template match="/*">
<table>
<xsl:apply-templates select="product[position() mod 3 = 1]" />
</table>
</xsl:template>
<xsl:template match="product">
<tr>
<xsl:apply-templates select="self::*|following-sibling::product[position() < 3]" mode="cell" />
</tr>
</xsl:template>
<xsl:template match="product" mode="cell">
<td>
<xsl:if test="position() < 3 and not(following-sibling::product[1])">
<xsl:attribute name="colspan">
<xsl:value-of select="4 - position()" />
</xsl:attribute>
</xsl:if>
<xsl:value-of select="#name" />
</td>
</xsl:template>
</xsl:stylesheet>
When appied to the sample XML, the following is output
<table>
<tr>
<td>Product 1</td>
<td>Product 2</td>
<td>Product 3</td>
</tr>
<tr>
<td>Product 4</td>
<td colspan="2">Product 5</td>
</tr>
</table>