Why does SGPLOT ignore my `MarkerSymbol` choices? - sas

Question

I'm creating a VLine plot with Proc SgPlot, with 4 groups of data. Here is my code to create the plot. (I've genericized the variable names, of course.) This is wrapped in a macro, but I don't think that makes any difference.
proc sgplot data=mydata;
vline NominalTime / Response=responseVariable Group=MyGroups stat=mean markers;
format MyGroups MyGroups.;
Where scaleNum=&scaleNum;
run;
I'm using Proc Template to customize the line colors, LineStyles, and MarkerSymbols. The Template code is below:
proc template;
define style Styles.MyNewStyle;
parent = styles.HTMLBlue;
style GraphBackground /
backgroundcolor=white;
style GraphData1 from GraphData1 /
markersymbol = "circle"
color = CXFFB44B
contrastcolor = CXFFB44B
;
style GraphData2 from GraphData2 /
markersymbol = "circle"
color = white
contrastcolor=CX000000
;
style GraphData3 from GraphData3 /
markersymbol = "Square"
color = CXD33183
contrastcolor=CXD33183
;
style GraphData4 from GraphData4 /
markersymbol = 'Square'
linestyle = 2
color = white
contrastcolor=CX555555
;
style GraphFonts from GraphFonts /
'GraphDataFont' = ("Arial",11pt)
'GraphValueFont' = ("Arial",11pt)
'GraphLabelFont' = ("Arial",11pt,bold)
'GraphFootnoteFont' = ("Arial",8pt)
'GraphTitleFont' = ("Arial",12pt,bold);
end;
run;
Of course, I've used ods html to change the output style:
ods html style=MyNewStyle;
Here is the crux of the question: the plot is generated with the colors as specified, but with incorrect markersymbol and linestyle assignments for groups 2 to 4. Stated another way, whatever markersymbol and linestyle I specify in GraphData1 is used for all of the lines in the plot, regardless of later assignments. Why is this happening?

Answer 1

The key to understanding this behavior is that starting with SAS 9.3, the HTML destination uses the HTMLBlue style by default. This style is a "Color priority" style, where only the color is rotated first. There are 12 defined colors. So, the first 12 group values get one of these 12 colors, with the first marker symbol and line pattern. After the first 12 groups, the next 12 groups get the second marker symbol and line pattern, with the 12 colors again.
With HTMLBlue, the other markers and line patterns will only show up after the first 12 group values.
Most other styles have attribute priority of "None". This means the all three attributes are rotated at the same time. So first group value gets color 1, symbol 1, and pattern 1. Second group value gets color 2, symbol 2, and pattern 2 and so on.
With SAS 9.4, the option ATTRPRIORITY was introduced in the Style definition and on the ODS GRAPHICS statement to control this behavior. Now, you can use this option to make any style rotate the attributes the way you want. To make HTMLBlue behave like LISTING, use the ODS Graphics option ATTRPRIORITY=none.

Answer 2

This works as expected:
proc template;
define style Styles.MyNewStyle;
parent = styles.HTMLBlue;
style GraphBackground /
backgroundcolor=white;
style GraphData1 from GraphData1 /
markersymbol = "circle"
color = CXFFB44B
contrastcolor = CXFFB44B
;
style GraphData2 from GraphData2 /
markersymbol = "circle"
color = white
contrastcolor=CX000000
;
style GraphData3 from GraphData3 /
markersymbol = "Square"
color = CXD33183
contrastcolor=CXD33183
;
style GraphData4 from GraphData4 /
markersymbol = 'Square'
linestyle = 2
color = white
contrastcolor=CX555555
;
style GraphFonts from GraphFonts /
'GraphDataFont' = ("Arial",11pt)
'GraphValueFont' = ("Arial",11pt)
'GraphLabelFont' = ("Arial",11pt,bold)
'GraphFootnoteFont' = ("Arial",8pt)
'GraphTitleFont' = ("Arial",12pt,bold);
end;
run;
data mydata;
do mygroups = 1 to 4;
do nominaltime=1 to 20;
responsevariable = mygroups*nominaltime;
output;
end;
end;
run;
ods html style=mynewstyle;
proc sgplot data=mydata;
vline NominalTime / Response=responseVariable Group=MyGroups stat=mean markers;
* format MyGroups MyGroups.;
* Where scaleNum=&scaleNum;
run;
ods html close;
If that works on your system, then you have a problem with your MyGroups. format or values, I suspect. What values does MyGroups have natively - 1-4 or something else that MyGroups. format converts to 1-4?
If that doesn't work on your system, give more system details - 9.3, 9.2, etc.?