parse user agent with Ragel - regex

Question

I have the following line from apache (changing the apache log format is not an option):
... referrer=- user_agent=JSON-RPC Client status=200 size=44 ...
and I am trying to parse it with Ragel. I am getting all the fields extracted except the user_agent. The user guide says that strong difference -- ensures that the first machine does NOT contain the second. In my case, I want to match anything that does not contain " status=", which would signify the next field. However, my current definition (below) appears to be skipping user_agent entirely; I still get status and following fields. Am I utilizing strong difference properly?
...
referrer = ^space+ >mark %{ emit("referrer"); };
user_agent = any* -- ' status=' >mark %{ emit("user_agent"); };
status = digit+ >mark %{ emit("status"); };
...
line = (
...
space "referrer="
referrer
space "user_agent="
user_agent
space "status="
status
space "size="
...
);

Answer 1

I know this question is old, but I'm just getting into Ragel and this may help others.
The problem here is operator precedence. The action operators > and % are evaluated before the strong difference operator --. It's easy to fix with parentheses:
user_agent = (any* -- ' status=') >mark %{ emit("user_agent"); };
I would also use space instead of hard-coding a space, at least for consistency:
user_agent = (any* -- (space 'status=')) >mark %{ emit("user_agent"); };

Answer 2

You can use state charts, try this state machine:
STATUS := digit+ ' ' #{ fnext SIZE; };
SIZE := digit+;
USER_AGENT =
start: (
's' -> s1 |
[^s] #{ if (!ua_start) ua_start = p; } -> start
),
s1: (
't' -> s2 |
[^t] -> start
),
s2: (
'a' -> s3 |
[^a] -> start
),
s3: (
't' -> s4 |
[^t] -> start
),
s4: (
'u' -> s5 |
[^u] -> start
),
s5: (
's' -> s6 |
[^s] -> start
),
s6: (
'=' #{ fnext STATUS; ua_stop = p - 7; } -> final |
[^=] -> start
)
;
main := "user_agent=" USER_AGENT ;
U can get the user agent in "ua_start" -> "ua_stop", for other variables, i think u already knew how to mark & get the characters.