Single shortcut to save-compile-execute C++ program in Emacs? - c++

Question

I have been trying to figure out a way to efficiently save a program, compile it and then run it in emacs. I have succeeded only partially in it.
I use smart-compile.el to make the job easier ( http://emacswiki.org/emacs/smart-compile.el ).
In that I have edited the C++ relevant portion to the below so that a program compiles and runs when I type M-x smart-compile RET followed by a RET.
(defcustom smart-compile-alist '(
;; g++-3 is used instead of g++ as the latter does not
;; work in Windows. Also '&& %n' is added to run the
;; compiled object if the compilation is successful
("\\.[Cc]+[Pp]*\\'" . "g++-3 -O2 -Wall -pedantic -Werror
-Wreturn-type %f -lm -o %n && %n")
..
To give an example, for a program sqrt.cpp, smart-compile auto generates following compile command:
g++-3 -O2 -Wall -pedantic -Werror -Wreturn-type sqrt.cpp -lm -o sqrt && sqrt
This works as long as my .cpp does not have any cin statement. For codes with cin statements, the console window shows the point where the user is supposed to input data. But I am unable to input anything and the Compilations status stays stuck at running.
In order to make the codes with user input work, I have to remove the && FILENAME part and then manually run ./FILENAME in emacs' eshell.
I am running emacs 24.3 in Windows. I have Cygwin installed and its bin added to the Windows environment variable Path (that's why g++-3 compilation works).
I would appreciate if someone could guide me how to save-compile-run user input required .cpp programs in emacs using a single command. Or at least how do I need to modify the above g++-3 command to make compile+run work for user input programs.
Thanks!

Answer 1

Emacs is programmable, so if something requires two steps, you can write a command that combines them. The simples code would look like this:
(defun save-compile-execute ()
(interactive)
(smart-compile 1) ; step 1: compile
(let ((exe (smart-compile-string "%n"))) ; step 2: run in *eshell*
(with-current-buffer "*eshell*"
(goto-char (point-max))
(insert exe)
(eshell-send-input))
(switch-to-buffer-other-window "*eshell*")))
The above code is simple, but it has one flaw: it doesn't wait for the compilation to finish. Since smart-compile doesn't support a flag for synchronous compilation, this must be achieved by temporarily hooking into the compilation-finish-functions, which makes the code more complex:
(require 'cl) ; for lexical-let
(defun do-execute (exe)
(with-current-buffer "*eshell*"
(goto-char (point-max))
(insert exe)
(eshell-send-input))
(switch-to-buffer-other-window "*eshell*"))
(defun save-compile-execute ()
(interactive)
(lexical-let ((exe (smart-compile-string "./%n"))
finish-callback)
;; when compilation is done, execute the program
;; and remove the callback from
;; compilation-finish-functions
(setq finish-callback
(lambda (buf msg)
(do-execute exe)
(setq compilation-finish-functions
(delq finish-callback compilation-finish-functions))))
(push finish-callback compilation-finish-functions))
(smart-compile 1))
The command can be run with M-x save-compile-execute RET or by binding it to a key.