Change order of list - xslt

Question

Current List
CurrentList
Access Autocad Burger
Layout Photoshop Sandwich
VisualStudio
I have used a boxed view and edited source like below to get three columns
<xsl:when test="$Position mod 3 = 0">
But the order of items needed is like this
Access Layout VisualStudio
Autocad Photoshop
Burger Sandwich
Can someone suggest a way to achieve this?
This is part of xml
<xsl:template name="NewTRJumbo" ddwrt:ghost="">
<xsl:param name="Position" select="1"/>
<xsl:param name="Collapse" select="."/>
<xsl:choose>
<xsl:when test="$Position mod 3 = 0">
<xsl:text disable-output-escaping="yes"></tr></xsl:text>
<xsl:call-template name="NewTR">
<xsl:with-param name="Collapse" select="$Collapse"/>
<xsl:with-param name="EmptyLine" select="1"/>
</xsl:call-template>
<xsl:text disable-output-escaping="yes"><td></td></tr></xsl:text>
<xsl:call-template name="NewTR">
<xsl:with-param name="Collapse" select="$Collapse"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<td width="1.5%">
</td>
</xsl:otherwise>
</xsl:choose>

Answer 1

I am assuming you have an XML document of elements, for example, something like this
<items>
<item>Access</item>
<item>Autocad</item>
<item>Burger</item>
<item>Layout</item>
<item>Photoshop</item>
<item>Sandwich</item>
<item>VisualStudio</item>
</items>
And you want to group them into 3 columns, but with the items running top-to-bottom first, rather than left-to-right. You current test of $Position mod 3 = 0 is partially along the right lines, but you are actually starting a new row each here, and so end up going left-to-right.
One thing to mention is your use of this line of code
<xsl:text disable-output-escaping="yes"></tr></xsl:text>
It looks like you are simply iterating over the elements, and trying to output a closing tr tag after every third one. XSLT is a functional language, so you need to approach with a different mind set, and do things differentially than you would in a normal procedural language.
Firstly, you need to find the number of rows you will beed to output
<xsl:param name="columns" select="3"/>
<xsl:variable name="items" select="count(/*/item)"/>
<xsl:variable name="rows" select="ceiling($items div $columns)"/>
i.e The rows is the total number of items divided by the number of columns.
Then, you need to select the first item of each row, which is straight-forward because these will be the first 'n' items in your list (Note the use of the mode because the final XSLT will have two templates matching the item element)
<xsl:apply-templates select="item[position() <= $rows]" mode="row"/>
Within the template matching the starting items, you then need to output the current item, and the following sibling items which are in the row
<xsl:apply-templates select=".|following-sibling::item[position() mod $rows = 0]"/>
The only other thing to consider is adding a blank cell to the end of the some rows. This can be done by calculating the number of remaining items compared to the total items
<xsl:variable name="lastItem" select="(position() + $rows * ($columns - 1) - $items)" />
<xsl:if test="$lastItem > 0">
<td colspan="{ceiling($lastItem div $rows)}"></td>
</xsl:if>
Try the following XSLT
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:param name="columns" select="3"/>
<xsl:variable name="items" select="count(/*/item)"/>
<xsl:variable name="rows" select="ceiling($items div $columns)"/>
<xsl:template match="/*">
<table>
<xsl:apply-templates select="item[position() <= $rows]" mode="row"/>
</table>
</xsl:template>
<xsl:template match="item" mode="row">
<tr>
<xsl:apply-templates select=".|following-sibling::item[position() mod $rows = 0]"/>
<xsl:variable name="lastItem" select="(position() + $rows * ($columns - 1) - $items)" />
<xsl:if test="$lastItem > 0">
<td colspan="{ceiling($lastItem div $rows)}"></td>
</xsl:if>
</tr>
</xsl:template>
<xsl:template match="item">
<td>
<xsl:value-of select="."/>
</td>
</xsl:template>
</xsl:stylesheet>
When applied to the XML shown at the beginning of the question, the following is output
<table>
<tr>
<td>Access</td>
<td>Layout</td>
<td>VisualStudio</td>
</tr>
<tr>
<td>Autocad</td>
<td>Photoshop</td>
<td colspan="1"></td>
</tr>
<tr>
<td>Burger</td>
<td>Sandwich</td>
<td colspan="1"></td>
</tr>
</table>