Outputting to a dataset while in a macro do loop - sas

Question

Here's a macro I'm writing, I want to look at a given data set, and write of each of the field(column) names as an observation into an info data set.
Here's what I've got
%macro go_macro(data);
/*get the list of field names from the dictionary*/
proc sql noprint;
select distinct name into :columns separated by ' '
from dictionary.columns
where memname = "%upcase(%scan(&data, -1))" and libname = "%upcase(%scan(&data, 1))" and type = "char"
;
quit;
/*now loop through this list of fieldnames*/
%let var_no = 1;
%let var = %scan(&columns, &var_no, ' ');
%do %while (&var ne);
/*here is where I want to write the fieldname to an observation*/
fname = "&var";
output;
%let var_no = %eval(&var_no +1);
%let var = %scan(&columns, &var_no, ' ');
%end;
%mend;
/*execute the code*/
data bdqa.accounts_info;
%go_macro(braw.accounts)
run;
this gives me
[MPRINT] Parsing Base DataServer
/* 0005 */ fname = "SORT_CODE";
/* 0006 */ output;
/* 0009 */ fname = "BANK_NAME";
/* 0010 */ output;
/* 0013 */ fname = "CREDIT_CARD";
/* 0014 */ output;
/* 0017 */ fname = "PRIMARY_ACCT_HOLDER";
/* 0018 */ output;
/* 0021 */ fname = "account_close_date";
/* 0022 */ output;
/* 0023 */ run;
ERROR: Parsing exception - aborting
ERROR: DS-00274 : Could not parse base DataServer code: Encountered " <ALPHANUM> "fname "" at line 5, column 9.
Was expecting one of:
<EOF>
";" ...
"*" ...
"data" ...
"proc" ...
(and 9 more)
while
while
data mytest;
do i = 1 to 5;
fname = 'hello world';
output;
end;
keep fname;
run;
is perfectly legit.
the following code
%macro char_freqs(data=);
/*get the different variables*/
proc sql noprint;
select distinct name into :columns separated by ' '
from dictionary.columns
where memname = "%upcase(%scan(&data, -1))" and libname = "%upcase(%scan(&data, 1))" and type = "char"
;
quit;
/*now get the distinct values for each of the variables*/
%let var_no = 1;
%let var = %scan(&columns, &var_no, ' ');
%do %while (&var ne);
proc freq data=&data;
tables &var/out=&var._freq;
run;
%let var_no = %eval(&var_no +1);
%let var = %scan(&columns, &var_no, ' ');
%end;
%mend;
%char_freqs(data=macros.businesses)
Also works - the PROC FREQ is allowed.

Answer 1

The problem is you have something like this:
data bdqa.accounts_info;
%go_macro(braw.accounts)
run;
->
data bdqa.accounts_info;
proc sql;
... select stuff ...;
quit;
fname = "stuff"; ...
run;
You need:
proc sql;
select stuff;
quit;
data bdqa.accounts_info;
fname = "stuff";
...
run;
You need to remove the PROC SQL from the macro - you can create a macro variable outside of a macro. Honestly you shouldn't use a macro for this at all - you can do one of two things:
a) Create the table directly from DICTIONARY.COLUMNS
proc sql;
create table bdqa.accounts_info as select name as fname from dictionary.columns where ... ;
quit;
b) Create it in a datastep
data bdqa.accounts_info;
__data = "&var_no";
do ... ;
run;
(the do loop is basically identical to the %do loop in the macro)