#echo off
pause
color 0a
mode 1000
set /p apps = where do you want to go to?
echo metrix = 1
echo nothing = 2
pause
if %apps% == 1 goto metrix
if %apps% == 2 goto nothing
:metrix
:start
echo %random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random% %random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random% %random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%%random%
goto start
:nothing
echo nothing
pause
exit
why doesnt it woerk?
I copied it from a tutorial and I have no idea why doesnt it work.
Remove the space before and after "=", in following statement.
set /p apps = where do you want to go to?
Besides CuriousMind's suggestion you should also do the comparison this way:
if "%apps%"=="1" goto metrix
if "%apps%"=="2" goto nothing
Using quotes and removing redundant spaces is safer. You probably also want to write
echo metrix = 1
echo nothing = 2
set /p apps = where do you want to go to?
so that the echos are displayed before the question.
Related
Hello to all my fellow StackOverflow members! I am trying to setup a somewhat basic script to help with checking user account details on a domain controller in a domain oriented Corp environment. One of the IT Service managers setup a very watered down script that basically just runs the following command:
net user /domain
I have tried to build a better script since we use this in so many of our customer environments it cuts down on guess work and time overall. The problem is at the end of the script I setup a direct back to the top of the script with a y/n prompt.. however, if you fail to press Y or N (case insensitive) and rather press j or 3 for example the script terminates. I have been extremely unsuccessful in setting up a basic error handling routine that states if the reported value is neither y nor n, echo a simple error string and then repeat the prompt. The following is my code for the setup (I have removed the previously attempts at setting up the looped routine for the y/n values. I have changed the values of the actual paths to each GOTO section so as not to share customer oriented information.
#ECHO OFF
:Start
SET uname=
cls
IF "%userdomain%"=="D1" GOTO 1
IF "%userdomain%"=="D2" GOTO 2
IF "%userdomain%"=="D3" GOTO 3
IF "%userdomain%"=="D4" GOTO 4
:1
ECHO You are on the D1 domain (%userdomain%)
ECHO Usernames should be in the format of firstname.lastname
ECHO.
SET /P uname=Username:
IF "%uname%"=="" GOTO Error
net user %uname% /domain
GOTO Request
:2
ECHO You are on the D2 Domain (%userdomain%)
ECHO Username format varies based on the creation of the ID.
ECHO.
SET /P uname=Username:
IF "%uname%"=="" GOTO Error
net user %uname% /domain
GOTO Request
:3
ECHO You are on the D3 Domain (%userdomain%)
ECHO Usernames are formatted as First Initial Last Name (auser)
ECHO.
SET /P uname=Username:
IF "%uname%"=="" GOTO Error
net user %uname% /domain
GOTO Request
:4
ECHO You are on the D4 Domain (%userdomain%)
ECHO Usernames are formatted as First Initial Last Name (auser)
ECHO.
SET /P uname=Username:
IF "%uname%"=="" GOTO Error
net user %uname% /domain
GOTO Request
:Error
ECHO.
ECHO Username was left blank, please enter a valid username and try again
ECHO.
TIMEOUT /T 5
GOTO Start
:Request
ECHO.
SET /P resp=Do you want to perform another lookup Y/N?
IF /I "%resp%"=="y" GOTO Start
IF /I "%resp%"=="n" exit
In the :Request section above I tried using IF /I NOT and IF NOT /I to begin the statement, as well as using a true false oriented value setting a variable to true, then making the statement say if not y if not n set variable to false, then using if false, repeat the loop, so far hitting any key other than y or n just exits the prompt.
Any help is appreciated, and thanks in advance!
You're using the wrong command, when only known inputs are required, use the choice.exe utility instead:
#ECHO OFF
:Start
CLS
ECHO You are on the D%USERDOMAIN:~-1% domain (%USERDOMAIN%)
ECHO Usernames should be in the format of firstname.lastname
ECHO(
SET "uname="
SET /P "uname=Username: "
IF NOT DEFINED uname GOTO Error
NET USER %uname% /DOMAIN
GOTO Request
:Error
ECHO(
ECHO Username was left blank, please enter a valid username and try again
ECHO(
TIMEOUT /T 5
GOTO Start
:Request
ECHO(
CHOICE /M "Do you want to perform another lookup"
IF NOT ERRORLEVEL 2 GOTO Start
Additional example with message before closing.
#ECHO OFF
:Start
CLS
ECHO You are on the D%USERDOMAIN:~-1% domain (%USERDOMAIN%)
ECHO Usernames should be in the format of firstname.lastname
ECHO(
SET "uname="
SET /P "uname=Username: "
IF NOT DEFINED uname GOTO Error
NET USER %uname% /DOMAIN
GOTO Request
:Error
ECHO(
ECHO Username was left blank, please enter a valid username and try again
ECHO(
TIMEOUT /T 5
GOTO Start
:Request
ECHO(
CHOICE /M "Do you want to perform another lookup"
IF NOT ERRORLEVEL 2 GOTO Start
ECHO(
ECHO Thank you and goodbye.
ECHO Press any key to exit. . .
TIMEOUT /T -1 >NUL
So. Currently I am working on a game where you create your own nation in Batch. There are bills passed by congress that you can either sign or veto. Once you do so, the bill disappears. After some time a new bill will pop up. The thing is there is a bill limit of 5, meaning that there can only be 5 bills waiting your approval at a time.
Here is the code so far.
:leg
title Borderlines BETA - Legislation
cls
echo =====
echo 1-Legislation (%notify_leg%) ===== 2-Disputes (%notify_disputes%) ===== 3-Mailbox (%notify_mailbox%)
echo =====
echo Legislation
if %notify_leg% GTR 0 (
echo You have new bills from Congress awating your approval!
) else (
echo Its been a slow day in %nation%...
)
echo ---
echo Select a bill...
echo %leg_01%
echo %leg_02%
echo %leg_03%
echo %leg_04%
echo %leg_05%
echo.
echo ---
echo A - Home
echo.
echo ---
set /p leg_choice=""
if %leg_choice%==A goto home
if %leg_choice%==1 goto leg
if %leg_choice%==2 goto disputes
if %leg_choice%==3 goto mail
if %leg_choice% GTR 3 goto bill_%leg_choice%
goto home
Basically %leg_01%, %leg_02%, and so on are the slots. When you create your nation, the bills are assigned. When you pass or veto a bill it removes the notification.
However lets say over time another bill gets added to the list. How can I have it so that once you sign or veto the bill it will remove it from the list, tell the program that a slot is available, and move up the remaining items all the way to the top. This would be essential because there could be, eventually, multiple bills in the game that will show up on that list.
Hope that makes sense ~
Does this suit your needs?
:newleg
if "%~1"=="" exit /b
for /l %%# in (4 -1 1) do (
set /a n=%%#+1
call set leg_0%%n%%=%%leg_0%%#%%
)
set leg_01=%~1
Call with call :newleg This_is_a_new_leg. All values will be shifted downwards, i.e. leg_05 is lost, the value of leg_04 is assigned to leg_05. leg_01 will be redefined as the specified parameter.
If you'd like to avoid quoting values with spaces while calling the function, you can use %* instead.
You can also keep the values of leg_06 and so on by increasing the limit in the for-loop (n-1, in this case "4").
You can delete an item from the list and then shift upwards with this function:
:delleg
if "%~1"=="" exit /b
set leg_0%1=
for /l %%# in (1 1 5) do if not defined leg_0%%# call :dl %%#
exit /b
:dl
set /a n=%1+1
for /l %%# in (%n% 1 6) do (
set /a n=%%#-1
call set leg_0%%n%%=%%leg_0%%#%%
)
exit /b
Call with call :delleg 2 to delete leg_02.
I've been struggling to write a script that will find the drive index number from other properties of the drive. The script is as follows:
#echo off
REM batch file to load Veracrypt
Set "driveIndex="
for /f "skip=1 tokens=1 delims= " %%a in ('wmic diskdrive where "model ='WD Elements 1078 USB Device'" get index') do SET driveIndex=%%a & goto reportLetter
:reportLetter
if not defined driveIndex (
echo Error Occured!
pause
exit
) else (
echo \Device\Harddisk%driveIndex:~0%\Partition3
pause
exit
)
However, the output of the script is \Device\Harddisk1 \Partition3. I tried for a long long time but could get the script to give the following output: \Device\Harddisk1\Partition3.
Could anyone tell me how to correct the code to get the required output?
Try this
DO SET "driveIndex=%%a"
Your line
... do set driveIndex=%%a & goto ...
is interpreted as set driveIndex=%%a<space>& goto ..., this is, where the additional space in \Device\Harddisk1 \Partition3 comes from.
Of course you could write:
... do set driveIndex=%%a& goto ...
but the better syntax is:
... do set "driveIndex=%%a" & goto ...
which eliminates any unintended spaces.
Note1: set is very picky with spaces. set var = hello creates a variable named var<space> with the value <space>hello<space>.
Note2:
set var="value" sets the value to "value"
set "var=value"sets the value to value. This syntax gives you full (and visible) control to the variable name and it's value.
#ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
SET DRIVE_INDEX=
FOR /F "usebackq skip=1" %%i IN (`wmic diskdrive where "model = 'HGST HTS725050A7E630 ATA Device'" get index`) DO (
IF "!DRIVE_INDEX!" EQU "" (SET DRIVE_INDEX=%%i)
)
ECHO DRIVE_INDEX is set to %DRIVE_INDEX%
I believe that the problem is that WMIC output is Unicode.
I'd try
for /f "skip=1 tokens=1 delims= " %%a in ('wmic diskdrive where "model ='WD Elements 1078 USB Device'" get index^|more') do SET driveIndex=%%a & goto reportLetter
where the ^|more converts to ANSI. The caret escapes the pipe to tell cmd that the pipe is part of the command to be executed.
So I am trying to add a timer to one of my if statements under a set command but I'm not sure what the command would be. The script will launch and wait thirty minutes before it reboots the PC or wait for a users input to input it at that time or cancel it. So I have my two if statements for the "restart now" and "cancel" set but now I need an if statement to have it count down from thirty minutes before it executes my restart command. Also if anyone knows how to add a visual timer on there showing how much time is left that would be a plus. Thanks guys!!!
#Echo off
:START
set /p answer=PC WILL RESTART IN 30 MINUTES, PRESS N TO RESTART NOW OR C TO CANCEL
if "%answer%"=="n" (GOTO Label1)
if "%answer%"=="c" (GOTO Label2)
if "TIMER GOES HERE" "==" (GOTO Label1)
:Label1
shutdown -r -t 60 -f
:Label2
exit
I reccomend using CHOICE.EXE, it comes standard with most versions of Windows (with the exception of Windows NT, 2000 and XP, it used to be downloadable from Microsoft's website, but they seem to have overlooked this* one on their ftp site.) and is simple to use.
#Echo off
:START
set waitMins=30
echo PC WILL RESTART IN %waitMins% MINUTES: Press N to restart [N]ow or C to [C]ancel
:: Calculate Seconds
set /a waitMins=waitMins*60
:: Choices are n and c, default choice is n, timeout = 1800 seconds
choice /c nc /d n /t %waitMins%
:: [N]ow = 1; [C]ancel = 2
goto Label%errorlevel%
:Label1
shutdown -r -t 60 -f
:: Make sure that the process doesn't fall through to Lable2
goto :eof
:Label2
exit
Simply CHOICE.EXE works like this...
choice
...and is the same as...
choice /c yn
...both will display...
[Y,N]?
...and both will wait for the user to press a Y or N.
Choice stores the result in %errorlevel%. Y=1, N=2.
The code I provided takes advantage of the default /D <choice> and timeout /T <seconds> options.
In example...
choice /c yn /d y /t 5
...gives the user a choice of Y or N, will wait for 5 seconds then automaticlly select the default choice of Y, resulting in %ERRORLEVEL%==1.
Another example is...
choice /c abcdef /m "Make a choice. "
...and it displays...
Make a choice. [A,B,C,D,E,F]?
...and...
A = %ERRORLEVEL% = 1
B = %ERRORLEVEL% = 2
C = %ERRORLEVEL% = 3
D = %ERRORLEVEL% = 4
E = %ERRORLEVEL% = 5
F = %ERRORLEVEL% = 6
There is no ERRORLEVEL 0.
For more on the use of choice, type CHOICE /? at the command prompt.
*NOTE The version of CHOICE.EXE I provided a link to uses slightly different commands, but provides the same functionality.
Similar one for hibernate.
#echo off
setlocal enableDelayedExpansion
for /l %%N in (600 -1 1) do (
set /a "min=%%N/60, sec=%%N%%60, n-=1"
if !sec! lss 10 set sec=0!sec!
cls
choice /c:CN1 /n /m "HIBERNATE in !min!:!sec! - Press N to hibernate Now, or C to Cancel. " /t:1 /d:1
if not errorlevel 3 goto :break
)
cls
echo HIBERNATE in 0:00 - Press N to hibernate Now, or C to Cancel.
:break
if errorlevel 2 (%windir%\System32\rundll32.exe powrprof.dll,SetSuspendState Hibernate) else echo Hibernate Canceled
Here is a really simple solution for Vista and Windows 7 that provides the timeout feature, but does not give a visual countdown.
#echo off
choice /c:CN /n /m "PC will restart in 30 minutes. Press N to restart Now, or C to Cancel" /t:1800 /d:N
if errorlevel 2 (shutdown -r -t 60 -f) else echo Restart Canceled
Here is a more complex solution for Vista and Windows 7 that provides a visual countdown, but it clears the console window each second. Also the timing is probably a bit off.
#echo off
setlocal enableDelayedExpansion
for /l %%N in (1800 -1 1) do (
set /a "min=%%N/60, sec=%%N%%60, n-=1"
if !sec! lss 10 set sec=0!sec!
cls
choice /c:CN1 /n /m "PC will restart in !min!:!sec! - Press N to restart Now, or C to Cancel. " /t:1 /d:1
if not errorlevel 3 goto :break
)
cls
echo PC will restart in 0:00 - Press N to restart Now, or C to Cancel.
:break
if errorlevel 2 (shutdown -r -t 60 -f) else echo Restart Canceled
If you need an XP solution then I think you will either need to download a non-native command line tool that asks for input with a timeout feature, or else switch to VBScript or JScript.
EDIT
Both scripts above can be adapted to run on XP by using the CHOICE.EXE download from the Microsoft FTP site that James K provided in his answer.
That version of CHOICE has slightly different syntax.
To adapt my first script, use:
choice /c:CN /n /t:N,1800 "PC will restart in 30 minutes. Press N to restart Now, or C to Cancel"
To adapt my second script, use:
choice /c:CN1 /n /t:1,1 "PC will restart in !min!:!sec! - Press N to restart Now, or C to Cancel. "
EDIT - Here is a crude VBS solution that is compatible with XP
Set objShell = CreateObject("WScript.Shell")
for i = 30 to 1 step -1
if i=1 then unit=" minute" else unit=" minutes"
rtn = objShell.Popup ( _
"The machine would like to Restart."&VbCrLf&VbCrLf& _
"Click OK to restart now"&VbCrLf& _
"Click Cancel or the [X] close button to abort the restart"&VbCrLf& _
"Do nothing and the machine will restart in "&i&unit, _
60, "Restart in "&i&unit, 1+48 _
)
if rtn <> -1 then exit for
next
if rtn <> 2 then objShell.Run "shutdown -r -f"
I think you can provide a more elegant VBS solution using HTA, but that is a lot more work, and I don't really know much about that technology.
I would use this code to make the script pause for a specified number of milliseconds:
PING 1.1.1.1 -n 1 -w <milliseconds> >NUL
This will send out 1 ping to the IP address 1.1.1.1 after <milliseconds> has elapsed. And the output of the ping command will be dismissed to NUL.
I recommend this script by SPC_75
its a .vbs file though, and for hibernate, but its easy to modify for sleep or shutdown.
'//*******************************************
'//hibernate.vbs
'//Purpose: Count Down to action (Hibernate)
'//Tested on Server 2008, Win 7 64bit, and XP
'//Author: SPC_75
'//Revision 1.3
'//Date: 1/09/2011
'//*******************************************
Option Explicit
Dim timeout, objShell, intReturn
Const wshOk = 1
Const wshOkDialog = 0
'Const wshIcon = 16 '/critical
'Const wshIcon = 32 '/question
Const wshIcon = 48 '/exclamation
'Const wshIcon = 64 '/information
timeout = 30 '/Timeout in seconds
Set objShell = CreateObject("Wscript.Shell")
Do Until timeout = 0
timeout = timeout - 1
intReturn = objShell.Popup(vbCrlf &"Hibernation about to initiate. Abort?"&vbCrlf & vbCrlf & vbCrlf & vbCrlf & "Time until hibernation : " & timeout, 1, "Hibernation", wshOkDialog + wshIcon + 4096)
If intReturn = wshOk Then
Wscript.Quit
End If
loop
objShell.Run "powercfg /hibernate on"
objShell.Run "shutdown -h"
objShell.Run "rundll32 powrprof.dll,SetSuspendState Hibernate" '/XP specific Hibernation command
set objShell = nothing
'//EOF
Works perfectly with a warning and timeout.
I need just something very simple like "run this command and succeed if there is 'this string' somewhere in the console output, fail otherwise". Is there such a tool?
Not that I'm aware of, but you can easily write one in another batch script.
call TestBatchScript.cmd > console_output.txt
findstr /C:"this string" console_output.txt
will set %errorlevel% to zero if the string is found, and nonzero if the string is absent. You can then test that with IF ERRORLEVEL 1 goto :fail and execute whatever code you want after the :fail label.
If you want compact evaluation of several such strings, you can use the || syntax:
call TestBatchScript.cmd > console_output.txt
findstr /C:"teststring1" console_output.txt || goto :fail
findstr /C:"teststring2" console_output.txt || goto :fail
findstr /C:"teststring3" console_output.txt || goto :fail
findstr /C:"teststring4" console_output.txt || goto :fail
goto :eof
:fail
echo You Suck!
goto :eof
Or, you can go even further and read the list of strings from a file
call TestBatchScript.cmd > console_output.txt
set success=1
for /f "tokens=*" %%a in (teststrings.txt) do findstr /C:"%%a" console_output.txt || call :fail %%a
if %success% NEQ 1 echo You Suck!
goto :eof
:fail
echo Didn't find string "%*"
set success=0
goto :eof
I use the following for filter type commands:
For batch file foo.cmd, create the following files:
foo.in.txt:
hello
foo.expected.txt:
hello world
foo.test.cmd:
#echo off
echo Testing foo.cmd ^< foo.in.txt ^> foo.out.txt
call foo.cmd < foo.in.txt > foo.out.txt || exit /b 1
:: fc compares the output and the expected output files:
call fc foo.out.txt foo.expected.txt || exit /b 1
exit /b 0
Then run foo.test.cmd
The below mentioned repo has been deleted and is unfortunately no longer available.
I have created a library for windows batch unit testing. It is currently in its infancy, but it works and I use it.
It is called cmdUnit and it can be downloaded from the project site on bitbucket:
https://bitbucket.org/percipio/cmdunit