ranking within rows of a data set [sas] - sas

Question

Suppose I've got a data set with n rows and p columns such that each entry in the data set contains a real number. I am looking for a way to rank the p columns within each row. The output of this ranking should be a length-p vector of ranks that accounts for ties.
So, let's say my data set has 5 columns. The first row could be something like row 1 = {10, 13, 3, 3, -4}. I'd like to perform some operations on this row and in the end get back the result row 1 ranks = {3, 4, 2, 2, 1}. The second row could be something like row 2 = {8, 3, -6, 5, 2} and the result on this row should be row 2 ranks = {5, 3, 1, 4, 2}.
Is this functionality implemented in SAS? I've generated code that doesn't account for ties, but they occur often enough that it would take an unreasonable amount of time to correct the row rankings that were done incorrectly.

Answer 1

Interesting question; here is one possible solution:
data have;
p1=10; p2=13; p3=3; p4=3; p5=-4; output;
p1=8; p2=3; p3=-6; p4=5; p5=2; output;
run;
data want;
set have;
array p(*) p1-p5;
array c(*) c1-c5;
array r(*) r1-r5;
/* Copy vector to temp array and sort */
do i=1 to dim(p);
c(i) = p(i);
end;
call sortn(of c(*));
/* Search new sorted array for the original position */
do i=1 to dim(c);
if i = 1 then rank=1;
else if c(i) ne c(i-1) then rank + 1;
do j=1 to dim(p);
if p(j) = c(i) then do;
r(j) = rank;
end;
end;
end;
/* PUT statement to see result in log */
put +3 p(*)
/ +3 c(*)
/ +3 r(*);
drop i j rank c1-c5;
run;

Answer 2

Sounds to me like you'll need several arrays to do this.
Array 1: Array to store the ranks
Array 2: Array to sort the values
Array 3: The original un-altered data
I don't have time right now to write the code but using someething like this would do a lot of the heavy lifting:
http://support.sas.com/kb/24/754.html

Answer 3

Might as well add this even though OP said he doesn't use IML in case others find this useful searching for it. IML is really the easiest way to solve this problem, since its fundamentally a vector/matrix problem...
proc iml;
p={10 13 3 3 -4, 5 6 5 2 3};
r=j(2,5,.);
print p r;
do i = 1 to nrow(p);
r[i,]=ranktie(p[i,]);
end;
print p r;
quit;
It does treat tries slightly differently from the OP, and thus would need some work to make it exactly like the solution requested - but in general, 1,2.5,2.5,4,5 [or 1,2,2,4,5] is probably what you really want, not 1,2,2,3,4. 4 and 5 should stay 4 and 5, not move up to 3 and 4, when 2 and 3 tie.

Answer 4

Just for fun, given the OP's answer to wanting a new dataset with ranks, here's the PROC RANK method. Probably not faster than a data step, but perhaps simpler and easier to use in multiple situations, and with the added advantage that you can't really make a mistake in the coding (without it actually crashing).
data have;
input id x1-x5;
datalines;
1 10 13 3 3 -4
2 5 6 5 2 3
;;;;
run;
proc transpose data=have out=temp;
by id;
var x1-x5;
run;
proc rank data=temp out=temprank;
var col1;
by id;
run;
proc transpose data=temprank out=want(drop=_name_ _label_);
by id;
var col1;
id _name_;
run;