OpenMP Fortran Default Clause - fortran

Question

This parallel works fine.
!$OMP PARALLEL Private(irep)
!$OMP DO
do irep = 1, nrep
print *, "Using thread: ", omp_get_thread_num(), "irep: ", irep
end do
!$OMP END DO NOWAIT
!$OMP END PARALLEL
This works fine too.
!$OMP PARALLEL
!$OMP DO
do irep = 1, nrep
print *, "Using thread: ", omp_get_thread_num(), "irep: ", irep
end do
!$OMP END DO NOWAIT
!$OMP END PARALLEL
Why does it return nothing when I use Default clause?
!$OMP PARALLEL DEFAULT(Private)
!$OMP DO
do irep = 1, nrep
print *, "Using thread: ", omp_get_thread_num(), "irep: ", irep
end do
!$OMP END DO NOWAIT
!$OMP END PARALLEL
Thank you so much!

Answer 1

Let's just take a look at a simpler case:
program testprivate
use omp_lib
integer :: nrep
nrep=16
!$OMP PARALLEL DEFAULT(Private)
print *, "Thread: ", omp_get_thread_num(), "sees nrep = ", nrep
!$OMP END PARALLEL
end program testprivate
We run this and get:
$ gfortran -o private private.f90 -fopenmp
$ export OMP_NUM_THREADS=8
$ ./private
Thread: 3 sees nrep = 0
Thread: 0 sees nrep = 0
Thread: 1 sees nrep = 32581
Thread: 7 sees nrep = 0
Thread: 4 sees nrep = 0
Thread: 5 sees nrep = 0
Thread: 2 sees nrep = 0
Thread: 6 sees nrep = 0
OpenMP private variables, whether private by default or otherwise, are undefined on entering the private section. That doesn't matter for the loop index, irep, which is set in the do loop; but if (say) your compiler is setting each thread's nrep to zero inside the private section then the loop will never execute. Worse, each thread could have different values for nrep and anything could happen.
So you don't want nrep to be private. You could still have default(private) shared(nrep), or even firstprivate(nrep), although there's no advantage here to having each thread have its own nrep.