XSLT 1.0 group by year and add the not existing year - xslt

Question

I have xml as below(using xslt 1.0):
<?xml version="1.0" encoding="utf-8"?>
<receives>
<receive>
<Year>2013</Year>
<money>120</money>
</receive>
<receive>
<Year>2013</Year>
<money>150</money>
</receive>
<receive>
<Year>2014</Year>
<money>130</money>
</receive>
<receive>
<Year>2011</Year>
<money>120</money>
</receive>
</receives>
I want to group-by the money by year, if the year is not in the list(as above xml, there is no 2011), I need to put 2012 in the result with totalamount=0 as following:
<year>2011</year>
<totalamount>120</totalamount>
<year>2012</year>
<totalamount>0</totalamount>
<year>2013</year>
<totalamount>270</totalamount>
<year>2014</year>
<totalamount>130</totalamount>
Cureently, I have finished the xslt as following:
<xsl:key name="receive-key" match="receive" use="Year" />
<xsl:template match="/receives">
<xsl:for-each
select="receive[generate-id() = generate-id(key('receive-key', Year))]">
<xsl:sort select="../receive[Year = current()/Year]/Year"></xsl:sort>
<year>
<xsl:value-of select="../receive[Year = current()/Year]/Year" />
</year>
<totalamount>
<xsl:value-of select="sum(../receive[Year = current()/Year]/money)" />
</totalamount>
</xsl:for-each>
</xsl:template>
This can only group the money by the existing year:
<year>2011</year>
<totalamount>120</totalamount>
<year>2013</year>
<totalamount>270</totalamount>
<year>2014</year>
<totalamount>130</totalamount>
Any idea about how to insert
<year>2012</year>
<totalamount>0</totalamount>
into the result?
Many thanks!

Answer 1

One way to do this could be with a named template, which is called with a parameter of a year. If this year does not exist in the key, output an empty value, and call it for the next year.
<xsl:template name="Year">
<xsl:param name="Year"/>
<xsl:if test="not(key('receive-key', $Year))">
<year>
<xsl:value-of select="$Year"/>
</year>
<totalamount>0</totalamount>
<xsl:call-template name="Year">
<xsl:with-param name="Year" select="$Year + 1"/>
</xsl:call-template>
</xsl:if>
</xsl:template>
So, as soon as it finds a year in the key, it will stop outputting the missing years.
One other thing to note, is one of the expressions in your XSLT
<xsl:value-of select="../receive[Year = current()/Year]/Year" />
This can actually be simplified to just this!
<xsl:value-of select="Year"/>
Similarly, you can change your sum to make use of the xsl:key for efficiency
<xsl:value-of select="sum(key('receive-key', Year)/money)"/>
Here is the full XSLT
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:key name="receive-key" match="receive" use="Year"/>
<xsl:template match="/receives">
<xsl:for-each select="receive[generate-id() = generate-id(key('receive-key', Year))]">
<xsl:sort select="Year"/>
<year>
<xsl:value-of select="Year"/>
</year>
<totalamount>
<xsl:value-of select="sum(key('receive-key', Year)/money)"/>
</totalamount>
<xsl:if test="position() != last()">
<xsl:call-template name="Year">
<xsl:with-param name="Year" select="number(Year) + 1"/>
</xsl:call-template>
</xsl:if>
</xsl:for-each>
</xsl:template>
<xsl:template name="Year">
<xsl:param name="Year"/>
<xsl:if test="not(key('receive-key', $Year))">
<year>
<xsl:value-of select="$Year"/>
</year>
<totalamount>0</totalamount>
<xsl:call-template name="Year">
<xsl:with-param name="Year" select="$Year + 1"/>
</xsl:call-template>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
When applied to your XML, the following is output
<year>2011</year>
<totalamount>120</totalamount>
<year>2012</year>
<totalamount>0</totalamount>
<year>2013</year>
<totalamount>270</totalamount>
<year>2014</year>
<totalamount>130</totalamount>