Javacc regular expression that matches all string except certain ones - regex

Question

What is the regular expression that'd match anything , except these strings:
=>, | ?
If you're familiar with javacc, I'm trying to define my ANYTHING token as shown below:
TOKEN :
{
<ARROW: "=>" >
|
<ANYTHING: (["\u0001" - "\uffdc"])+>
|
<PIPE: "|">
|
<UPPER_CHAR: (["A"-"Z"])>
}
Thanks

Answer 1

Try something like this:
Test.jj
options {
STATIC = false ;
}
PARSER_BEGIN(Test)
public class Test {
public static void main(String[] args) throws Exception {
Test parser = new Test(new java.io.StringReader("foo=>bar=baz|done"));
parser.Parse();
}
}
PARSER_END(Test)
TOKEN :
{
< ARROW : "=>" >
| < PIPE : "|" >
| < ANYTHING : (~["=", "|"] | "=" ~[">"])+ >
}
void Parse() :
{}
{
(Any())* <EOF>
}
void Any() :
{Token t;}
{
( t=<ARROW> {System.out.println("ARROW = '" + t.image + "'");}
| t=<PIPE> {System.out.println("PIPE = '" + t.image + "'");}
| t=<ANYTHING> {System.out.println("ANYTHING = '" + t.image + "'");}
)
}
Generate the parser classes:
javacc Test.jj
and run the main method:
java Test
will print the following for the input "foo=>bar=baz|done":
ANYTHING = 'foo'
ARROW = '=>'
ANYTHING = 'bar=baz'
PIPE = '|'
ANYTHING = 'done'

Answer 2

You are probably best off to use lexical states. Here is an RE solution that might work
("=")+ | ( ~["=","|"] | ("=")* ~["=","|",">"] )+ ("=")*
By the way I changed the question a little so that the empty string is not an "anything", so this re should match any string that is not empty and does not contain any "|"s nor any "=>"s.