Calculate sum of array elements without sum function - xslt

Question

I am new to xslt. I have a xml file like
<EmpCollection>
<Emp>
<Name>Sai</Name>
<Sal>7000</Sal>
</Emp>
<Emp>
<Name>Nari</Name>
<Sal>7400</Sal>
</Emp>
<Emp>
<Name>Hari</Name>
<Sal>9000</Sal>
</Emp>
<Emp>
<Name>Suri</Name>
<Sal>8900</Sal>
</Emp>
</EmpCollection>
Now I want to add sum of salaries without using sum() function.
I want to learn xslt in a clear way:-)

Answer 1

I. Probably one of the simplest solutions:
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="Sal">
<xsl:param name="pSum" select="0"/>
<xsl:apply-templates select="following::Sal[1]">
<xsl:with-param name="pSum" select="$pSum + ."/>
</xsl:apply-templates>
</xsl:template>
<xsl:template match="Sal[not(following::Sal)]">
<xsl:param name="pSum" select="0"/>
<xsl:value-of select="$pSum + ."/>
</xsl:template>
<xsl:template match="/">
<xsl:apply-templates select="descendant::Sal[1]"/>
</xsl:template>
</xsl:stylesheet>
When this transformation is applied on the provided XML document:
<EmpCollection>
<Emp>
<Name>Sai</Name>
<Sal>7000</Sal>
</Emp>
<Emp>
<Name>Nari</Name>
<Sal>7400</Sal>
</Emp>
<Emp>
<Name>Hari</Name>
<Sal>9000</Sal>
</Emp>
<Emp>
<Name>Suri</Name>
<Sal>8900</Sal>
</Emp>
</EmpCollection>
the wanted, correct result is produced:
32300
II. A more general solution is to use the FXSL 2.x f:foldl() function like this:
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/" exclude-result-prefixes="f">
<xsl:import href="../f/func-foldl.xsl"/>
<xsl:import href="../f/func-Operators.xsl"/>
<xsl:output encoding="UTF-8" omit-xml-declaration="yes"/>
<xsl:template match="/">
<xsl:value-of select="f:foldl(f:add(), 0, /*/*/Sal)"/>
</xsl:template>
</xsl:stylesheet>
When this XSLT 2.0 transformation is applied on the same XML document (above), the same correct and wanted result is produced:
32300
You can pass any two-argument function as argument to f:foldl() and produce the solutions of different problems.
For example, passing f:mult() instead of f:add() (and changing the "zero" argument to 1) produces the product of the salaries:
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/" exclude-result-prefixes="f">
<xsl:import href="../f/func-foldl.xsl"/>
<xsl:import href="../f/func-Operators.xsl"/>
<xsl:output encoding="UTF-8" omit-xml-declaration="yes"/>
<xsl:template match="/">
<xsl:value-of select="f:foldl(f:mult(), 1, /*/*/Sal)"/>
</xsl:template>
</xsl:stylesheet>
The result of applying this transformation to the same XML document is now the product of all Sal elements:
4.14918E15
III. In XSLT 3.0 (XPath 3.0) one can use the standard fold-left() or fold-right() function in exactly the same way as in the previous solution.

Answer 2

There are probably more elegant ways (and I guess sum() :) but the following works, by 'folding' siblings with addition. The termination condition is the last sibling (i.e. with no following nodes)
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">
<xsl:output method="xml" omit-xml-declaration="yes"/>
<xsl:template match="/EmpCollection">
<result>Result Is : <xsl:apply-templates select="Emp[1]"/>
</result>
</xsl:template>
<xsl:template match="Emp[following-sibling::Emp]">
<xsl:variable name="salThis">
<xsl:value-of select="Sal"/>
</xsl:variable>
<xsl:variable name="salOthers">
<xsl:apply-templates select="following-sibling::Emp[position()=1]"/>
</xsl:variable>
<xsl:value-of select="$salThis + $salOthers"/>
</xsl:template>
<!--Termination - the last employee just returns its salary value-->
<xsl:template match="Emp[not(following-sibling::Emp)]">
<xsl:value-of select="Sal"/>
</xsl:template>
</xsl:stylesheet>
Gives the Result:
<result>Result Is : 32300</result>
Edit
After reading your question again, I guess this isn't a code golf question?
The below is a more simple way to do this with hard coded element names, which instructs the processor to add together the salaries of the named employees:
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">
<xsl:output method="xml" omit-xml-declaration="yes"/>
<xsl:template match="/EmpCollection">
<result>
Result Is : <xsl:value-of select="Emp[Name='Sai']/Sal + Emp[Name='Nari']/Sal + Emp[Name='Hari']/Sal + Emp[Name='Suri']/Sal"/>
</result>
</xsl:template>
</xsl:stylesheet>
which should then lead easily to understand what sum() is doing:
<xsl:template match="/EmpCollection">
<result>
Result Is : <xsl:value-of select="sum(Emp/Sal)"/>
</result>
</xsl:template>
Edit
Count is simply:
<xsl:template match="/EmpCollection">
<result>
<xsl:text>Count Is : </xsl:text>
<xsl:value-of select="count(Emp)"/>
</result>
</xsl:template>
Doing this without count() isn't as simple. Note that xsl:variables cannot be changed once assigned (immutable). So the following doesn't work at all.
<xsl:template match="/EmpCollection">
<xsl:variable name="count" select="0" />
<xsl:for-each select="Emp">
<!--NB : You can't do this. Variables are immutable - XSLT is functional -->
<xsl:variable name="count" select="$count + 1"></xsl:variable>
</xsl:for-each>
<result>
Result Is : <xsl:value-of select="$count"/>
</result>
</xsl:template>
So you could 'loop' through all the nodes, and then use position() to determine if this is the last node in the sequence. (Note that we've used for-each, but in practice it is better to use use apply-template)
<xsl:template match="/EmpCollection">
<result>
<xsl:text>Count Is : </xsl:text>
<xsl:for-each select="Emp">
<xsl:if test="position() = last()">
<xsl:number value="position()" format="1" />
</xsl:if>
</xsl:for-each>
</result>
</xsl:template>
:(