What does this Arduino code do? - c++

Question

I understand what most of this is doing, however, the
if (digitalRead(miso)) { d |= 1; }
Is a line that I dont understand. THis code is from the Adafruit MAX31855 library which is used for Arduino boards. I am trying to port the code to my C8051F020 MCU in c. This code reads from a thermocouple and the MAX31855 is the digital interface to the MCU. here is the whole code for this file. I am not familiar with digitalRead(). The if statement posted above is where I am failing to interpret. This if statement is in the uint32_t Adafruit_MAX31855::spiread32(void) function.
/***************************************************
This is a library for the Adafruit Thermocouple Sensor w/MAX31855K
Designed specifically to work with the Adafruit Thermocouple Sensor
----> https://www.adafruit.com/products/269
These displays use SPI to communicate, 3 pins are required to
interface
Adafruit invests time and resources providing this open source code,
please support Adafruit and open-source hardware by purchasing
products from Adafruit!
Written by Limor Fried/Ladyada for Adafruit Industries.
BSD license, all text above must be included in any redistribution
****************************************************/
#include "Adafruit_MAX31855.h"
#include <avr/pgmspace.h>
#include <util/delay.h>
#include <stdlib.h>
Adafruit_MAX31855::Adafruit_MAX31855(int8_t SCLK, int8_t CS, int8_t MISO) {
sclk = SCLK;
cs = CS;
miso = MISO;
//define pin modes
pinMode(cs, OUTPUT);
pinMode(sclk, OUTPUT);
pinMode(miso, INPUT);
digitalWrite(cs, HIGH);
}
double Adafruit_MAX31855::readInternal(void) {
uint32_t v;
v = spiread32();
// ignore bottom 4 bits - they're just thermocouple data
v >>= 4;
// pull the bottom 11 bits off
float internal = v & 0x7FF;
internal *= 0.0625; // LSB = 0.0625 degrees
// check sign bit!
if (v & 0x800)
internal *= -1;
//Serial.print("\tInternal Temp: "); Serial.println(internal);
return internal;
}
double Adafruit_MAX31855::readCelsius(void) {
int32_t v;
v = spiread32();
//Serial.print("0x"); Serial.println(v, HEX);
/*
float internal = (v >> 4) & 0x7FF;
internal *= 0.0625;
if ((v >> 4) & 0x800)
internal *= -1;
Serial.print("\tInternal Temp: "); Serial.println(internal);
*/
if (v & 0x7) {
// uh oh, a serious problem!
return NAN;
}
// get rid of internal temp data, and any fault bits
v >>= 18;
//Serial.println(v, HEX);
// pull the bottom 13 bits off
int16_t temp = v & 0x3FFF;
// check sign bit
if (v & 0x2000)
temp |= 0xC000;
//Serial.println(temp);
double centigrade = v;
// LSB = 0.25 degrees C
centigrade *= 0.25;
return centigrade;
}
uint8_t Adafruit_MAX31855::readError() {
return spiread32() & 0x7;
}
double Adafruit_MAX31855::readFarenheit(void) {
float f = readCelsius();
f *= 9.0;
f /= 5.0;
f += 32;
return f;
}
uint32_t Adafruit_MAX31855::spiread32(void) {
int i;
uint32_t d = 0;
digitalWrite(sclk, LOW);
_delay_ms(1);
digitalWrite(cs, LOW);
_delay_ms(1);
for (i=31; i>=0; i--)
{
digitalWrite(sclk, LOW);
_delay_ms(1);
d <<= 1;
if (digitalRead(miso)) {
d |= 1;
}
digitalWrite(sclk, HIGH);
_delay_ms(1);
}
digitalWrite(cs, HIGH);
//Serial.println(d, HEX);
return d;
}

Answer 1

DigitalRead
Reads the value from a specified digital pin, either HIGH or LOW.
MISO (Master In Slave Out): the input of the Master's shift register, and the output of the Slave's shift register.
SPI overview
| is the bitwise OR operator.
d |= 1 is the shorthand notation for
d = d | 1
This code sets the last bit of d to 1 if the condition is true.
So what you're doing is reading the output of the slave register, and if it's 1, it's setting the last bit of d to 1. Right before that line, it shifts d left by one bit with d <<= 1;. And it does this in a loop:
Shift d left 1 bit
Read miso, if it's 1, set the least significant bit of d to 1.
repeat

Answer 2

MISO is the Master In/Slave Out pin on an SPI bus. In this code you're playing the part of the Master, so that is the pin where you read input from the slave. d |= 1 is just setting the last bit in d to 1 if it read a 1 from the slave (and all of the other bits will be unaffected). Every iteration it sets the last (LSB) bit of d to 1 if it read a 1, and then at the beginning of the next iteration it shifts d to the left.

Answer 3

I have no experience at all with this API, however...
If you view the digitalRead() documentation, all the function does is read the bit on the pin that you supply as an argument. It returns either HIGH or LOW.
So basically, what I see: if miso bit is on, make the first bit in d on.