Simple Script With Logging - list

Question

I am trying to write a script that will copy files from folder A to folder B, it will copy only files that come from a list file.
I then need it to log any files that failed to copy. Here is what I have so far, I just cannot get logging to work.
Option Explicit
Dim Sour, Dest
Dim oFSO, sFile, oFile, sText
Dim objFSO, objFileCopy
Dim strFilePath, strDestination, strSource
Const ForReading = 1, ForWriting = 2, ForAppending = 8
strLoggingFiles = "C:\failedtransfer.txt"
strSource = InputBox("Enter source path information") 'Enter your source path here
strDestination = InputBox("Enter destination path information") 'Enter your destination path here
'Set the read of the input file and prompt for location
Set oFSO = CreateObject("Scripting.FileSystemObject")
sFile = InputBox("Enter path to text document with files to be copied:")
'Open the read, get the file name of the file to be copied, and copy it to new location
If oFSO.FileExists(sFile) Then
Set oFile = oFSO.OpenTextFile(sFile, ForReading)
Do While Not oFile.AtEndOfStream
sText = oFile.ReadLine
If (Trim(sText) <> "") And _
oFSO.FileExists(strSource & "\" & sText) Then
oFSO.CopyFile strSource & "\" & sText, strDestination
Else
WScript.Echo "Couldn't find " & strSource & "\" & sText
End If
Loop
oFile.Close
Else
WScript.Echo "The file was not there."
End If

Answer 1

Here's the code. It'll log the source file names (full path) if they are missing or failed when being copied. Please note that in Vista/Win7+, you'll need Administrator rights if you want to put a file in the root directory.
Option Explicit
Dim Sour, Dest
Dim oFSO, oLog, sFile, oFile, sText
Dim objFSO, objFileCopy
Dim strFilePath, strDestination, strSource
Const ForReading = 1, ForWriting = 2, ForAppending = 8
strLoggingFiles = "C:\failedtransfer.txt"
strSource = InputBox("Enter source path information") 'Enter your source path here
strDestination = InputBox("Enter destination path information") 'Enter your destination path here
'Set the read of the input file and prompt for location
Set oFSO = CreateObject("Scripting.FileSystemObject")
sFile = InputBox("Enter path to text document with files to be copied:")
'Open the read, get the file name of the file to be copied, and copy it to new location
If oFSO.FileExists(sFile) Then
'Open/create log file
set oLog = oFSO.OpenTextFile(strLoggingFiles, ForAppending, True)
Set oFile = oFSO.OpenTextFile(sFile, ForReading)
Do While Not oFile.AtEndOfStream
sText = oFile.ReadLine
If (Trim(sText) <> "") And _
oFSO.FileExists(strSource & "\" & sText) Then
On Error Resume Next 'disable quit on error
oFSO.CopyFile strSource & "\" & sText, strDestination
If Err.Number <> 0 Then
oLog.WriteLine strSource & "\" & sText 'log failed copy
End If
On Error Goto 0 'enable quit on error
Else
WScript.Echo "Couldn't find " & strSource & "\" & sText
oLog.WriteLine strSource & "\" & sText 'log failed copy 'log missing source
End If
Loop
oFile.Close
oLog.Close 'close log file
Else
WScript.Echo "The file was not there."
End If

Answer 2

At some point I got tired of writing logging routines over and over again, so I wrote a class (CLogger) as an abstraction layer for logging to different facilities (console, eventlog, file):
Set clog = New CLogger
clog.LogFile = "C:\failedtransfer.txt"
clog.LogToConsole = False
clog.LogToEventlog = False
'...
On Error Resume Next
oFSO.CopyFile strSource & "\" & sText, strDestination
If Err Then
clog.LogError strSource & "\" & sText & ": " & FormatErrorMessage(Err)
End If
On Error Goto 0
'...