Regular expression to match strings with embedded spaces - regex

Question

I am trying to write a regular expression but I can't pass the words space
I have a data file like this (generated by another utility)
* field : 100
blahbla : <Set>
scree : <what>
.Cont.asasd :
Othreaol : Value, Other value
Point->IP : 0.0.0.0 Port 5060
The pattern has to match and capture data like this
"field" "100"
"blahbla" "<Set>"
"scree" "<what>"
".Cont.asasd" ""
"Othreaol" "Value, Other value"
My early solution is
/^([\s\*]+)([\w]+[\s\.\-\>]{0,2}[\w]+)(\s*\:\s)(.*)/
but I have problem with some strings like
Z.15 example : No
the space stops the pattern from matching
H.25 miss here : No
same thing here

Answer 1

There are some complicated answers here. I think I'd use a simple split:
while( <DATA> ) {
chomp;
my( $field, $value ) = split /\s*:\s*/, $_, 2;
print "Field [$field] value [$value]\n";
}
__DATA__
* field : 100
blahbla : <Set>
scree : <what>
.Cont.asasd :
Othreaol : Value, Other value
Point->IP : 0.0.0.0 Port 5060
This gives:
Field [* field] value [100]
Field [blahbla] value [<Set>]
Field [scree] value [<what>]
Field [.Cont.asasd] value []
Field [Othreaol] value [Value, Other value]
Field [Point->IP] value [0.0.0.0 Port 5060]
From there, I'd filter the names and values as needed instead of trying to do it all in a single regex:
my #pairs =
grep { $_->[0] !~ /->/ } # filter keys
map { $_->[0] =~ s/\A\*\s+//; $_ } # transform keys
map { chomp; [ split /\s*:\s*/, $_, 2 ] } # parse line
<DATA>;
use Data::Printer;
p #pairs;
__DATA__
* field : 100
blahbla : <Set>
scree : <what>
.Cont.asasd :
Othreaol : Value, Other value
Point->IP : 0.0.0.0 Port 5060

Answer 2

Since you want to separate the values by colon, use the complement of that character in your regex for all those characters before the split.
my $regex
= qr{
( # v- no worry, this matches the first non-space, non-colon
[^\s:]
(?> [^:\n]* # this matches all non-colon chars on the line
[^\s:] # match the last non-space, non-colon, if there
)? # but possibly not there
) # end group
\s* # match any number of whitespace
: # match the colon
\s* # followed by any number of whitespace
( \S # Start second capture with any non space
(?> .* # anything on the same line
\S # ending in a non-space
)? # But, possibly not there at all
| # OR
) # nothing - this gives the second capture as an
# empty string instead of an undef
}x;
while ( <$in> ) {
$hash{ $1 } = $2 if m/$regex/;
}
%hash then looks like this:
{ '* field' => '100'
, '.Cont.asasd' => ''
, 'H.25 miss here' => 'No'
, Othreaol => 'Value, Other value'
, 'Point->IP' => '0.0.0.0 Port 5060'
, 'Z.15 example' => 'No'
, blahbla => '<Set>'
, scree => '<what>'
}
Of course, as I begin to think on it, if you could be assured of a /\s+:\s+/ pattern or at least a /\s{2,}:\s{2,}/ pattern, it might be simpler to just split the line like so:
while ( <$in> ) {
if ( my ( $k, #v )
= grep {; length } split /\A\s+|\s+\z|(\s+:\s+)/
) {
shift #v; # the first one will be the separator
$hash{ $k } = join( '', #v );
}
}
It does the same thing, at does not have to do nearly as much backtracking to trim results. And it ignores escaped colons without a whole lot more syntax, because it has to be a bare colon surrounded by spaces. You could just simply add the following to the if block:
$k =~ s/(?<!\\)(\\\\)*\\:/$1:/g;

Answer 3

I don't understand why the Point->IP line is omitted from your example output, but something like the code below should suit you.
use strict;
use warnings;
while (<DATA>) {
next unless /([^\s*].+?)\s*:\s*(.*?)\s*$/;
printf qq("%s" "%s"\n), $1, $2;
}
__DATA__
* field : 100
blahbla : <Set>
scree : <what>
.Cont.asasd :
Othreaol : Value, Other value
Point->IP : 0.0.0.0 Port 5060
Z.15 example : No
H.25 miss here : No
output
"field" "100"
"blahbla" "<Set>"
"scree" "<what>"
".Cont.asasd" ""
"Othreaol" "Value, Other value"
"Point->IP" "0.0.0.0 Port 5060"
"Z.15 example" "No"
"H.25 miss here" "No"