How to repeat XSLT child nodes of the same name? - xslt

Question

I have an xml dump of a transaction that I want to create a report from.
The (simplified) xml structure looks like:
Subject
id
name
license
event id=key
result
eventtype
date
action
charge id=key
result
code
date
...etc
There is only one id, name, and license for every subject; but there could be many events, and many charges for each subject--each one having a different result.
The report output is a table type, with each subject having a header of name, id, license, and multiple blocks of data transactions listed below the header. Each data block has different values and structure based on the type of transaction.
It works perfectly for the header, and one each of the data transaction types, but only the first event transaction and the first charge transaction will print out.
The (simplified) xsl looks like:
<xsl:for-each select="file/subject">
<xsl:if test="not (#subject = preceding-sibling::subject[1])">
<table width="754" border="2" cellpadding="0">
<tr>
<td width="172">ctn: <strong><xsl:value-of select="id"/></strong></td>
<td width="364">defendant: <strong><xsl:value-of select="name"/></strong></td>
<td width="200">sid: <strong><xsl:value-of select="license"/></strong></td>
</tr>
</table>
</xsl:if>
<blockquote>
<xsl:if test="event/eventType != ' '">
<table width="695" border="1">
<tr>
<td>Event<xsl:value-of select="event/result"/></td>
<td>Eventtype<xsl:value-of select="event/eventtype"/></td>
<td>Date<xsl:value-of select="event/date"/></td>
</tr>
</table>
</xsl:if>
<xsl:if test="charge/code != ' '">
<table width="695" border="1">
<tr>
<td>Charge<xsl:value-of select="charge/result"/></td>
<td>Code<xsl:value-of select="charge/code"/></td>
<td>Date<xsl:value-of select="charge/date"/></td>
</tr>
</table>
</xsl:if>
</blockquote>
</xsl:for-each>
I assume that I need an additional for-each to scan the child nodes, but adding the additional loop just gives me the headers.
Any thoughts?
(and thanks for taking the time to read this far. :o)

Answer 1

Where possible in XSLT, avoid for-each and apply your nodes to transformation templates instead.
I came up with this, which you can run at this playground session - not sure if it's broadly what you're after.
<!-- root and static content -->
<xsl:template match="/">
<xsl:apply-templates select='root/Subject' />
</xsl:template>
<!-- iteration content: subject -->
<xsl:template match='Subject'>
<table>
<tr>
<td>ctn: <strong><xsl:value-of select="id"/></strong></td>
<td>defendant: <strong><xsl:value-of select="name"/></strong></td>
<td>sid: <strong><xsl:value-of select="license"/></strong></td>
</tr>
</table>
<xsl:apply-templates select='event' />
<xsl:apply-templates select='charge' />
</xsl:template>
<!-- iteration content: event -->
<xsl:template match='event'>
<blockquote>
<table>
<tr>
<td>Event: <xsl:value-of select="result"/></td>
<td>Event type: <xsl:value-of select="eventtype"/></td>
<td>Date: <xsl:value-of select="date"/></td>
</tr>
</table>
</blockquote>
</xsl:template>
<!-- iteration content: charge -->
<xsl:template match='charge'>
<blockquote>
<table>
<tr>
<td>Charge: <xsl:value-of select="result"/></td>
<td>Code: <xsl:value-of select="code"/></td>
<td>Date: <xsl:value-of select="date"/></td>
</tr>
</table>
</blockquote>
</xsl:template>