Insert element at specific point in output document during XSLT transformation - xslt

Question

I am wondering if you can access the result-document during processing.
The reason I ask is that I am transforming an input document and would like to insert elements depending on some conditions but this would have to occur when I have traversed the tree and I am nearly at end of creating it.
The transformed xml looks something similar to this:
<xform>
<xforms>
<model>
<instance>
<data />
<data />
</instance>
</model>
<bind />
<bind />
<bind />
</xforms>
</xform>
I intend, during transformation (before the above xml is serialized), to access the <instance> tag and insert additional <data> elements.
Note
The input document is different from the above xml - the above xml is what the transformation should produce.
Similarly, I would want to access the <xform> element and insert additional <bind> nodes.
So the final document would look like this (assuming I added 2 data nodes and 2 bind nodes):
<xform>
<xforms>
<model>
<instance>
<data />
<data />
<data>new data node</data>
<data>second new data node</data>
</instance>
</model>
<bind />
<bind />
<bind />
<bind>new bind node</bind>
<bind>second new bind node</bind>
</xforms>
</xform>
Any help is appreciated.

Answer 1

No, you can't access a result-document, you can however create temporary trees in variables and then process them again, if needed with templates with a different mode. So instead of e.g.
<xsl:template match="/">
<xsl:result-document href="example.xml">
<xform>
<xforms>
<model>
<instance>
<data>
</data>
</instance>
</model>
<bind />
<bind />
<bind />
</xforms>
</xform>
</xsl:result-document>
</xsl:template>
you would create the first result in a variable and then process it further as in e.g.
<xsl:template match="#* | node()">
<xsl:copy>
<xsl:apply-templates select="#* | node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="/">
<xsl:variable name="temp1">
<xform>
<xforms>
<model>
<instance>
<data>
</data>
</instance>
</model>
<bind />
<bind />
<bind />
</xforms>
</xform>
</xsl:variable>
<xsl:result-document href="example.xml">
<xsl:apply-templates select="$temp1/*"/>
</xsl:result-document>
</xsl:template>
<xsl:template match="instance">
<xsl:copy>
<xsl:apply-templates/>
<data>...</data>
</xsl:copy>
</xsl:template>
That sample does not use modes but I often use them with variables and different processing steps to cleanly seperate the templates for each step from other steps.

Answer 2

Yes, the way to do this is with multi-pass processing:
<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="node()|#*" mode="#default pass2">
<xsl:copy>
<xsl:apply-templates select="node()|#*" mode="#current"/>
</xsl:copy>
</xsl:template>
<xsl:template match="/">
<xsl:variable name="vPass1">
<xsl:apply-templates/>
</xsl:variable>
<xsl:apply-templates select="$vPass1/node()" mode="pass2"/>
</xsl:template>
<xsl:template match="instance" mode="pass2">
<instance>
<xsl:apply-templates mode="pass2"/>
<data>2</data>
<data>3</data>
</instance>
</xsl:template>
<xsl:template match="model" mode="pass2">
<model>
<xsl:apply-templates mode="pass2"/>
<bind>1</bind>
<bind>2</bind>
<bind>3</bind>
</model>
</xsl:template>
</xsl:stylesheet>
when this transformation is applied on the provided XML document:
<xform>
<xforms>
<model>
<instance>
<data>
</data>
</instance>
</model>
<bind />
<bind />
<bind />
</xforms>
</xform>
it transforms it to itself using the identity rule and the result of this first pass is captured in the variable $vPass1. Then the second pass processes the current results in $vPass1 and adds two new data children under the instance element and three bind children under the model element -- so the final result is:
<xform>
<xforms>
<model>
<instance>
<data/>
<data>2</data>
<data>3</data>
</instance>
<bind>1</bind>
<bind>2</bind>
<bind>3</bind>
</model>
<bind/>
<bind/>
<bind/>
</xforms>
</xform>