apply the whole template or template parts depending on the condition - xslt

Question

I have the template
<xsl:template match="node" mode="some_mode">
<xsl:value-of select="child1" />
<xsl:value-of select="child2" />
<xsl:value-of select="child3" />
</xsl:template>
I want to apply the template so it would select all the nodes specified in the template in one case like this
<xsl:apply-templates select="node" mode="some_node" /> <!-- select all inside the node tag -->
and in another case I want to limit the output and for example not to select <child1> or <child2> nodes. Can I do it with a variable or a param? Or do I have to write another template from scratch?
<xsl:apply-templates select="node" mode="some_node" /> <!-- select only some tags from the node tag -->
In other word I will use this templates several times and I want to contorl the output when applying. I can define the variable, but the documentation says that I can't change the value of a variable once it was defined. Probably the param will wrok but I'm not good with it.

Answer 1

I'm afraid that's not possible without modification of the template you have.
You could think about storing template output in a variable and then processing it to remove child1 and child2 values. But I guess you would be unable to guess which part of your output is coming from child1 and/or child2.
Or you can develop another template that performs that alternative action.
EDIT: Another idea:
Maybe it is possible to apply filtering to get rid of child1 and child2 before applying your template (that would be a sort of multi-pass XSL tranformation).

Answer 2

Use the xsl:if instruction inside your template to branch.
Example:
<xsl:template match="node">
<xsl:value-of select="child1" />
<xsl:if test="price > 10">
<xsl:value-of select="child2" />
<xsl:value-of select="child3" />
</xsl:if>
</xsl:template>
I was hoping for a simple example in the question. As of the face-of-it one is not forthcoming, I'll make up a simple example here, which emodies your question, and show you how the xsl:if instruction is the perfect answer.
Let's say you have a music collection like so ...
<?xml version="1.0"?>
<catalog>
<cd>
<title>Empire Burlesque</title>
<artist>Bob Dylan</artist>
<country>USA</country>
<company>Columbia</company>
<price>10.90</price>
<year>1985</year>
</cd>
<cd>
<title>Hide your heart</title>
<artist>Bonnie Tyler</artist>
<country>UK</country>
<company>CBS Records</company>
<price>9.90</price>
<year>1988</year>
</cd>
</catalog>
And you want to output a html table of your CD's listing title and price. Normally you want both title and price, but on some conditions (say price is less than $10), you want to suppress the output of price, and just have some static text in its place, like "cheaper than 10.00".
So your expected output should be:
<?xml version="1.0" encoding="utf-8"?>
<table>
<tr>
<td>Empire Burlesque</td>
<td>cheaper than 10.00</td>
</tr>
<tr>
<td>Hide your heart</td>
<td>9.90</td>
</tr>
</table>
The style-sheet to produce this transformation could be:
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:template match="/">
<table>
<xsl:apply-templates select="//cd"/>
</table>
</xsl:template>
<xsl:template match="cd">
<tr>
<td><xsl:value-of select="title"/></td>
<xsl:if test="price < 10">
<td><xsl:value-of select="price"/></td>
</xsl:if>
<xsl:if test="not(price < 10)">
<td>cheaper than 10.00</td>
</xsl:if>
</tr>
</xsl:template>
</xsl:stylesheet>
And there you have the perfect answer - how to apply the whole template or just parts of it depending on a condition. In this case the condition is that the price is less than $10.

Answer 3

I recommend using separate templates with different match patterns and/or in different modes. This is to be preferred to using conditionals and thus writing messy and potentially buggy code:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:template match="/">
<xsl:apply-templates mode="allChildren"/>
==========
<xsl:apply-templates mode="child3Only"/>
</xsl:template>
<xsl:template match="node" mode="allChildren">
<xsl:copy-of select="*"/>
</xsl:template>
<xsl:template match="node" mode="child3Only">
<xsl:copy-of select="child3"/>
</xsl:template>
</xsl:stylesheet>
When this transformation is applied on the following document (similar to the one you used in a previous question):
<document>
<node>
<child1>Child 1</child1>
<child2>Child 2</child2>
<child3>Child 3</child3>
</node>
<anotherNode />
</document>
the wanted result is produced:
<child1>Child 1</child1><child2>Child 2</child2><child3>Child 3</child3>
==========
<child3>Child 3</child3>