how to convert xsl dateformat? - xslt

Question

How to convert
01/29/2012 00:00
to
Monday, Jan 29, 2012
in xslt?

Answer 1

I. An XSLT 1.0 solution (not producing the day of the week), which is much simpler and shorter than other answers :
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:my="my:my">
<xsl:output method="text"/>
<my:months>
<m>Jan</m><m>Feb</m><m>Mar</m><m>Apr</m><m>May</m><m>Jun</m>
<m>Jul</m><m>Aug</m><m>Sep</m><m>Oct</m><m>Nov</m><m>Dec</m>
</my:months>
<xsl:variable name="vMonthNames" select=
"document('')/*/my:months/*"/>
<xsl:template match="text()">
<xsl:variable name="vnumMonth" select="substring-before(., '/')"/>
<xsl:variable name="vDay" select=
"substring-before(substring-after(., '/'), '/')"/>
<xsl:variable name="vYear" select=
"substring-before(substring-after(substring-after(., '/'), '/'), ' ')"/>
<xsl:value-of select=
"concat($vMonthNames[0+$vnumMonth], ' ',
$vDay, ', ',
$vYear
)"/>
</xsl:template>
</xsl:stylesheet>
When this transformation is applied on the following XML document:
<t>01/29/2012 00:00</t>
the wanted result is produced:
Jan 29, 2012
II.In XSLT 2.0 one can use very powerful date-time functions, such as format-dateTime().
<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:template match="text()">
<xsl:variable name="vComps" select=
"tokenize(., '/')"/>
<xsl:variable name="vstdDate" select=
"concat(substring-before($vComps[3], ' '), '-',
$vComps[1], '-',
$vComps[2]
)"/>
<xsl:sequence select=
"format-date(xs:date($vstdDate), '[FNn], [MNn] [D], [Y]')"/>
</xsl:template>
</xsl:stylesheet>
When this transformation is applied on the same XML document (above), the wanted, correct result is produced:
Sunday, January 29, 2012

Answer 2

Source : http://geekswithblogs.net/workdog/archive/2007/02/08/105858.aspx#110623
" I've modified to convert "1/20/2007 10:22:28 PM" to "January 20, 2007" ... to save anyone who finds it useful a few minutes.
<xsl:template name="FormatDate">
<!-- expected date format 1/20/2007 10:22:28 PM [OR] 01/20/2007 10:22:28 PM -->
<xsl:param name="DateTime" />
<!-- new date format January 20, 2007 -->
<xsl:variable name="mo">
<xsl:value-of select="substring-before($DateTime,'/')" />
</xsl:variable>
<xsl:variable name="day-temp">
<xsl:value-of select="substring-after($DateTime,'/')" />
</xsl:variable>
<xsl:variable name="day">
<xsl:value-of select="substring-before($day-temp,'/')" />
</xsl:variable>
<xsl:variable name="year-temp">
<xsl:value-of select="substring-after($day-temp,'/')" />
</xsl:variable>
<xsl:variable name="year">
<xsl:value-of select="substring($year-temp,1,4)" />
</xsl:variable>
<xsl:choose>
<xsl:when test="$mo = '1' or $mo = '01'">January</xsl:when>
<xsl:when test="$mo = '2' or $mo = '02'">February</xsl:when>
<xsl:when test="$mo = '3' or $mo = '03'">March</xsl:when>
<xsl:when test="$mo = '4' or $mo = '04'">April</xsl:when>
<xsl:when test="$mo = '5' or $mo = '05'">May</xsl:when>
<xsl:when test="$mo = '6' or $mo = '06'">June</xsl:when>
<xsl:when test="$mo = '7' or $mo = '07'">July</xsl:when>
<xsl:when test="$mo = '8' or $mo = '08'">August</xsl:when>
<xsl:when test="$mo = '9' or $mo = '09'">September</xsl:when>
<xsl:when test="$mo = '10'">October</xsl:when>
<xsl:when test="$mo = '11'">November</xsl:when>
<xsl:when test="$mo = '12'">December</xsl:when>
</xsl:choose>
<xsl:value-of select="' '"/>
<xsl:if test="(string-length($day) < 2)">
<xsl:value-of select="0"/>
</xsl:if>
<xsl:value-of select="$day"/>
<xsl:value-of select="', '"/>
<xsl:value-of select="$year"/>
</xsl:template>
"

Answer 3

Apologies for this horribly complicated solution, but it'll give you exactly what you want in XSLT 1.0:
<xsl:variable name="months" select="'JanFebMarAprMayJunJulAugSepOctDec'" />
<xsl:variable name="weekdays" select="'Monday Tuesday WednesdayThursday Friday Saturday Sunday '" />
<xsl:template match="date">
<xsl:variable name="days">
<xsl:value-of select="
((substring(.,7,4) - 1970) * 365)+floor((substring(.,7,4) - 1970) div 4)+
substring('000,031,059,090,120,151,181,212,243,273,304,334,365',substring(.,1,2)*4-3,3)+
(substring(.,4,2)-1)+
(1-floor(((substring(.,7,4) mod 4) + 2) div 3))*floor((substring(.,1,2)+17) div 20)
" />
</xsl:variable>
<xsl:value-of select="concat(
normalize-space(substring($weekdays,(($days+3) mod 7) * 9 + 1, 9)),
', ',
substring($months,substring(.,1,2) * 3 - 2, 3),
' ',
substring(.,4,2) + 0,
', ',
substring(.,7,4)
)" />
</xsl:template>
The construction of the variable 'days' uses a fairly complicated formula that determines the number of days since 1/1/1970. It's a simple matter from there to add 3 (because 1/1/1970 was a Thursday) and take the mod 7 of this figure to get the day of the week from the weekdays variable with substr.
If you're going to be working with dates a lot though, get XSLT2!