Checking for values in XSLT and condition - xslt

Question

Rephrasing my question properly:
I have XSLT where I need to check for node values for specific data.
E.g. (pseudocode):
If only H occurs then set target element value as 'H'
Else if
Only B or N then set target element value as 'BN'
If Source XML:
<n1>N</n1>
<n1>B</n1>
<n1>N</n1>
Target node:
BN
If Source XML:
<n1>H</n1>
<n1>H</n1>
<n1>H</n1>
Target node:
H
There is no attribute. I have to only set text on meeting the condition in the target node.
Can I use something like:
<xsl:variable name="elements">
<xsl:for-each select="/test/elem">
<xsl:value-of select="."/>
<xsl:if test="position() < last()">
</xsl:if>
</xsl:for-each>
</xsl:variable>
Would the above give me concat of all element values and then I can do a check to see the if that contains x then I can do a set text?

Answer 1

When this stylesheet
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:template match="/">
<xsl:variable name="value">
<xsl:choose>
<xsl:when test="/root[not(n1 != 'H')]">
<xsl:value-of select="'H'"/>
</xsl:when>
<xsl:when test="/root[not(n1[. != 'B' and . != 'N'])]">
<xsl:value-of select="'BN'"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="'Something else'"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:text>$value = </xsl:text>
<xsl:value-of select="$value"/>
</xsl:template>
</xsl:stylesheet>
is given this input
<root>
<n1>H</n1>
<n1>H</n1>
<n1>H</n1>
</root>
it produces the desired output
$value = H
Similarly with
<root>
<n1>N</n1>
<n1>B</n1>
<n1>N</n1>
</root>
or with
<root>
<n1>N</n1>
<n1>N</n1>
<n1>N</n1>
</root>
we get
$value = BN
And with
<root>
<n1>N</n1>
<n1>B</n1>
<n1>x</n1>
</root>
or with
<root>
<n1>N</n1>
<n1>B</n1>
<n1>H</n1>
</root>
we get
$value = Something else
The string H, BN or Something else is the value of a variable. Instead of just outputting the value of that variable you can of course set it as the contents of a new element you create.