String showing as NodeSet in next iteration - XSLT - xslt

Question

This must be easy, but I am not able to figure it out.
Aim is to replace '95' with '3F' if Substring length before '95' is an even number. If Substring length before '95' is not an even number, take the value of sub-string alongwith the value of '9' in '95' and start looking for occurrence of 95 again recursively to replace the value.
Final string will have value replaced with '3F'
A string value is assigned to 'inputHex' variable. The same is passed to the 'inputHexStr' for invoking a template replace95. In the given string first value of '95' occurs at position 134 and 135. therefore the condition not(string-length(substring-before($inputHexStr,$from)) mod 2 = 0) gets invoked. Problem is... in the next invocation to 'replace95' template with the remaining value of string, the string is not accessible and debug shows as a nodeset.
Why is that ?
Update - for the input xml as <x/> the next iteration is changing the context to the root node of the given xml file and the value of inputHexStr is shown as nodeset instead of string.
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="text"/>
<xsl:template match="/">
<xsl:variable name="inputHex"
select="'3C3F786D6C2076657273696F6E3D22312E302220656E636F64696E673D227574662D3822203F3E3C783E74686973206973206120626164206368617261637465722019520737472696E6720646174613C2F7895'"/>
<xsl:variable name="hexResult">
<xsl:call-template name="replace95">
<xsl:with-param name="inputHexStr" select="$inputHex"/>
</xsl:call-template>
</xsl:variable>
<xsl:value-of select="$hexResult"/>
</xsl:template>
<xsl:template name="replace95">
<xsl:param name="inputHexStr" select="."/>
<xsl:param name="from" select="'95'"/>
<xsl:param name="to" select="'3F'"/>
<xsl:choose>
<xsl:when test="not(contains($inputHexStr,$from))">
<xsl:value-of select="$inputHexStr"/>
</xsl:when>
<xsl:otherwise>
<xsl:if test="string-length(substring-before($inputHexStr,$from)) mod 2 = 0">
<xsl:value-of select="substring-before($inputHexStr,$from)"/>
<xsl:value-of select="$to"/>
<xsl:call-template name="replace95">
<xsl:with-param name="inputHexstr"
select="substring-after($inputHexStr,$from)"/>
<xsl:with-param name="from" select="$from"/>
<xsl:with-param name="to" select="$to"/>
</xsl:call-template>
</xsl:if>
<xsl:if test="not(string-length(substring-before($inputHexStr,$from)) mod 2 = 0)">
<xsl:variable name="no95part"
select="substring($inputHexStr,1,string-length(substring-before($inputHexStr,$from))+1)"/>
<xsl:value-of select="$no95part"/>
<xsl:variable name="no95Length" select="string-length($no95part)"/>
<xsl:call-template name="replace95">
<xsl:with-param name="inputHexstr" select="substring($inputHexStr,$no95Length+1)"/>
<xsl:with-param name="from" select="$from"/>
<xsl:with-param name="to" select="$to"/>
</xsl:call-template>
</xsl:if>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>

Answer 1

I think this is because of a typo when you recursively call your templates with parameters.
<xsl:with-param name="inputHexstr" select=...
You have a lower case s here. XSLT is case-sensitive, so it should be a capital S
<xsl:with-param name="inputHexStr" select=...
Note that, it might be worth combining your two xls:if statements into a single xsl:choose to avoid extra calculations on the remainder
<xsl:choose>
<xsl:when test="not(contains($inputHexStr,$from))">...</xsl:when>
<xsl:when test="string-length(substring-before($inputHexStr,$from)) mod 2 = 0">...</xsl:when>
<xsl:otherwise>...</xsl:otherwise>
</xsl:choose>