Power BI: Is there a way to get the a value based on the MAX date? - powerbi

Question

I am trying to make a calculated column in Power BI to return the last Job Title held for the name listed based on the maximum/latest date.
Current Title = VAR MaxDate =CALCULATE (MAX('Terms FY23'[Employee History.Date])) VAR EEID = CALCULATE(MAX('Terms FY23'[Employee History.Employee]))RETURN CALCULATE(FIRSTNONBLANK(SELECTCOLUMNS(FILTER('Terms FY23','Terms FY23'[Employee History.Date] = MaxDate && 'Terms FY23'[Employee History.Employee] = EEID),"JobTitle",'Terms FY23'[Employee History.Title]),_MaxDate))
I tried this but it returned the same exact Job Title column.
Date Full Name Job Title
10/31/2022 John Adams Landscaper I
11/30/2022 John Adams Crew Leader
12/31/2022 John Adams Crew Leader
1/31/2023 John Adams Crew Leader
2/15/2023 John Adams Crew Leader

Answer 1

For you sample data this one works
Last Job Title =
VAR MAXDATE =
MAXX('Table', 'Table'[Date])
RETURN
CALCULATE(
MAX('Table'[Job Title]),
FILTER(
ALL('Table'),
'Table'[Date] = MAXDATE
)
)

Answer 2

In case you have more than one distinct name in the table can go via this
calculated table
Lookup Table =
SUMMARIZE(
'Table',
'Table'[Full Name],
"Last Job Titel", CALCULATE(
MIN('Table'[Job Title]),
'Table'[Date] = MAX('Table'[Date])
)
)
to end up with this calulated column
Last Job Title=
LOOKUPVALUE(
'Lookup Table'[Last Job Titel],
'Lookup Table'[Full Name], 'Table'[Full Name]
)

Answer 3

You can add a calculated column that does this directly using the new INDEX windowing function as a filter argument, that uses ALLEXCEPT on your table to provide the correct row context:
Last Title =
CALCULATE (
SELECTEDVALUE ( 'Terms FY23'[Employee History.Title] ),
INDEX (
1,
ALLEXCEPT ( 'Terms FY23', 'Terms FY23'[Employee History.Name] ),
ORDERBY ( [Employee History.Date], DESC )
)
)
This type of calculation would normally require to store the maximum date value first, and then solve for the title:
Last Title Old =
VAR _max_date =
CALCULATE (
MAX ( 'Terms FY23'[Employee History.Date] ),
ALLEXCEPT ( 'Terms FY23', 'Terms FY23'[Employee History.Name] )
)
RETURN
CALCULATE (
SELECTEDVALUE ( 'Terms FY23'[Employee History.Title] ),
ALLEXCEPT ( 'Terms FY23', 'Terms FY23'[Employee History.Name] ),
'Terms FY23'[Employee History.Date] = _max_date
)
NB! If you have two people in this table with the same name, you are out of luck. You would need a more robust way of handling employees, for example by using a unique employee ID instead of some arbitrary name.