Create an average table excluding some values - powerbi

Question

I have a table with this structure:
Date
DeviceID
Value
01/01/2022
SensorA
1200
01/01/2022
SensorB
1300
01/01/2022
SensorC
900
02/01/2022
SensorA
500
02/01/2022
SensorB
50
02/01/2022
SensorC
39
I'm interesting in create a new table that have the average by day of all sensors values but excluding the values which are lower than the average of all sensors by day.
For example for 01/01/2022 the average of all sensors values is:
(1200+1300+900) / 3 = 1133.3
We then calculate the average sensor value for the day, excluding SensorC because its value is below 1133.3:
(1200+1300) / 2 = 1250
The final table have to looks like this:
Date
Value
01/01/2022
1250
02/01/2022
500
Is it possible? Hope you can help me
Thanks in advance!

Answer 1

This does exactly what you are asking for:
Avg Excl =
VAR _avg = AVERAGE ( 'Table'[Value] )
RETURN
CALCULATE (
AVERAGE ( 'Table'[Value] ) ,
'Table'[Value] > _avg
)
Result:
If you want to persist a DAX table to your model, you just use this code together with SUMMARIZE:
New_Table =
SUMMARIZE (
'Table' ,
'Table'[Date] ,
"Value",
VAR _avg = AVERAGE ( 'Table'[Value] )
RETURN
CALCULATE (
AVERAGE ( 'Table'[Value] ) ,
'Table'[Value] > _avg
)
)
Result:
For good measure, here is some Power Query code to achieve the same result. Usually this is best practice due to compression efficiency and such in Power BI. As a bonus, it also makes working with the pbix file smoother since you don't have to wait for the table to recalculate all the time when you add/remove/edit DAX components.
This solution is your best bet if this his how you actually want your table to look, since you can get rid of the original table in the model altogether and not have it in the model as a dependency. You can paste this into a blank query:
let
Source = Table.FromRecords({
[Date="2022-01-01", DeviceID="SensorA",Value=1200],
[Date="2022-01-01", DeviceID="SensorB",Value=1300],
[Date="2022-01-01", DeviceID="SensorC",Value=900],
[Date="2022-01-02", DeviceID="SensorA",Value=500],
[Date="2022-01-02", DeviceID="SensorB",Value=50],
[Date="2022-01-02", DeviceID="SensorC",Value=39]
}),
#"Changed Type" = Table.TransformColumnTypes(Source,{
{"Date", type date},
{"DeviceID", type text},
{"Value", Int64.Type}
}),
#"Grouped Rows" = Table.Group(#"Changed Type", {"Date"}, {
{"Avg", each List.Average([Value]), type nullable number},
{"Data", each _, type table [Date=nullable date, DeviceID=nullable text, Value=nullable number]}
}),
#"Expanded Data" = Table.ExpandTableColumn(#"Grouped Rows", "Data", {"Value"}, {"Data.Value"}),
#"Added Custom" = Table.AddColumn(#"Expanded Data", "Custom", each if [Data.Value] > [Avg] then [Data.Value] else null),
#"Grouped Rows1" = Table.Group(#"Added Custom", {"Date"}, {{"Avg Value", each List.Average([Custom]), type nullable number}})
in
#"Grouped Rows1"

Answer 2

Since you are using the Device ID column in the table, it shows all of them separately. Can you remove the DeviceID column and try the value column as average?