For-each loop with fn:tokenize - xslt

Question

I want to take the value of variable, tokenize it, and loop through the different tokens.
My solutions does not work as expected. I must be misunderstanding what tokenize() actually does.
<xsl:variable name="topicCode">1.2.3.4</xsl:variable>
<xsl:variable name="tokenizedTopicCode"><xsl:value-of select="tokenize($topicCode,'\.')"/></xsl:variable>
<mdcomplex name="Topic">
<xsl:for-each select="distinct-values($tokenizedTopicCode)">
<xsl:if test="position()=1">
<md name="chaptercode">
<xsl:attribute name="value"><xsl:value-of select="."/></xsl:attribute>
</md>
</xsl:if>
<xsl:if test="position()=2">
<md name="sectioncode">
<xsl:attribute name="value"><xsl:value-of select="concat($tokenizedTopicCode[position()=1],'.',.)"/></xsl:attribute>
</md>
</xsl:if>
<xsl:if test="position()=3">
<md name="subsectioncode">
<xsl:attribute name="value"><xsl:value-of select="concat($tokenizedTopicCode[position()=1],'.',$tokenizedTopicCode[position()=2],'.',.)"/></xsl:attribute>
</md>
</xsl:if>
<xsl:if test="position()=4">
<md name="topiccode">
<xsl:attribute name="value"><xsl:value-of select="concat($tokenizedTopicCode[position()=1],'.',$tokenizedTopicCode[position()=2],'.',$tokenizedTopicCode[position()=3],.)"/></xsl:attribute>
</md>
</xsl:if>
</xsl:for-each>
</mdcomplex>
Expected:
<mdcomplex name="Topic">
<md name="chaptercode" value="1"/>
<md name="sectioncode" value="1.2"/>
<md name="subsectioncode" value="1.2.3"/>
<md name="topiccode" value="1.2.3.4"/>
</mdcomplex>
Actual:
<mdcomplex name="Topic">
<md name="chaptercode" value="1 2 3 4"/>
</mdcomplex>
I also added a <xsl:message> right after the start of the <xsl:for-each> loop:
<xsl:for-each select="distinct-values($tokenizedTopicCode)">
<xsl:message><xsl:value-of select="."/></xsl:message>
I expected it to output the value of the different tokens (1, 2, 3, 4). Instead, it outputs all tokens in one go: "1 2 3 4".
How can I split the variable into the different tokens and loop through them?
I am using Saxon 9.9.1.7 on Oxygen.

Answer 1

Key learning points here:
(1) xsl:value-of constructs a single text node. You're splitting a string into tokens using tokenize(), and then you're immediately stringing them back together using xsl:value-of.
(2) xsl:variable, with no select or as attribute, constructs an XML document tree. Again that's going to munge your tokens together.
If you want a variable to contain a sequence of strings, do
<xsl:variable name="t" select="tokenize(...)" as="xs:string*"/>
Technically the as attribute here is redundant, but it's generally good practice to include it, because it helps both the human reader and the XSLT compiler spot any mistakes in your code.

Answer 2

You at least need <xsl:variable name="tokenizedTopicCode" select="tokenize($topicCode,'\.')"/> instead of <xsl:variable name="tokenizedTopicCode"><xsl:value-of select="tokenize($topicCode,'\.')"/></xsl:variable>.
I don't see, however, how you expect to select stuff in e.g. $topicCode with a positional predicate, that variable is not a sequence of items.

Answer 3

I think you want something like:
<xsl:variable name="topicCode">1.2.3.4</xsl:variable>
<xsl:variable name="tokenizedTopicCode" select="tokenize($topicCode,'\.')"/>
<xsl:variable name="names" select="('chapter', 'section', 'subsection', 'topic')"/>
<mdcomplex name="Topic">
<xsl:for-each select="1 to count ($tokenizedTopicCode)">
<md name="{$names[current()]}code">
<xsl:attribute name="value">
<xsl:value-of select="$tokenizedTopicCode[position() le current()]" separator="."/>
</xsl:attribute>
</md>
</xsl:for-each>
</mdcomplex>
Not sure why you would want to use distinct-values() here; isn't 1.1.1.1 a valid topic code?