Overlapping periods value summary on chart in Power BI - powerbi

Question

I don't know what I'm looking for maybe that is why I can't find solution online.
Just trying to show a data on simple chart with time axis.
Example of data I have:
ID
StartTime
EndTime
Quantity
1
11:00:00
12:00:00
10
2
11:30:00
12:20:00
10
3
12:00:00
13:00:00
10
4
13:40:00
14:00:00
10
5
13:50:00
15:00:00
10
Now on chart I would like to show:
Axis
Value on Chart
11:00:00
10
11:15:00
10
11:30:00
20
11:45:00
20
12:00:00
20
12:15:00
20
12:30:00
10
12:45:00
10
...
...
So overlapping period values should show on chart as sum.
Axis interval 15 min is just for example, but if required it could be fixed to 10 or 15 minutes.

Answer 1

In PQ M code you could:
Create a list of ALL the 15 minute bins from the earliest Start to the Latest end
Create a list of the 15 minute bins for each row Start..End
Join the two with JoinType.FullOuter
Group by the bin, return the Sum for each interval and Sort
Source
M Code
let
Source = Table.FromRows(Json.Document(Binary.Decompress(Binary.FromText("i45WMlTSUTI0tDIwACIQ0wjBNFCK1YlWMoIoMEYoMEJVYIymzRjdBBOIqAlM1ARdgSlEgSlM1BRFQSwA", BinaryEncoding.Base64), Compression.Deflate)), let _t = ((type nullable text) meta [Serialized.Text = true]) in type table [ID = _t, StartTime = _t, EndTime = _t, Quantity = _t]),
//set data types
#"Changed Type" = Table.TransformColumnTypes(Source,{
{"ID", Int64.Type}, {"StartTime", type time}, {"EndTime", type time}, {"Quantity", Int64.Type}}),
//create List of all 15 minute intervals from earliest Start time to latest End time
quarterHours = List.Times(
List.Min(#"Changed Type"[StartTime]),
Duration.TotalMinutes(
List.Max(#"Changed Type"[EndTime]) - List.Min(#"Changed Type"[StartTime]))/15,#duration(0,0,15,0)),
//compute a List of 15 minute bins for each row
// where Start Time is rounded down to the 15 minute interval; and End Time is rounded up to the 15 minute interval
#"Added Custom" = Table.AddColumn(#"Changed Type", "Time Bin",
each List.Transform(
{Number.RoundDown(Number.From([StartTime])*96,0)..Number.RoundUp(Number.From([EndTime])*96,0)-1},
each _/96)),
//expand the Time Bin list to one entry per 15 minute interval
//and set the data type
#"Expanded Custom" = Table.ExpandListColumn(#"Added Custom", "Time Bin"),
#"Changed Type1" = Table.TransformColumnTypes(#"Expanded Custom",{{"Time Bin", type time}}),
//Join the column that has ALL of the 15 minute bins (so as to account for those intervals with no entries
addAllTimes = Table.Join(#"Changed Type1","Time Bin",
Table.FromColumns({quarterHours},type table[Bin=Time.Type]),"Bin",JoinKind.FullOuter),
//Group by Bin and Sort by time
#"Grouped Rows" = Table.Group(addAllTimes, {"Bin"}, {{"Quantity", each List.Sum([Quantity]), type nullable number}}),
#"Sorted Rows" = Table.Sort(#"Grouped Rows",{{"Bin", Order.Ascending}})
in
#"Sorted Rows"
Results

Answer 2

Define a new table corresponding to the Axis column you show and then write a measure to use for the values along these lines:
ChartValue =
VAR CurrTime = SELECTEDVALUE ( NewTable[Axis] )
RETURN
CALCULATE (
SUM ( Data[Amount] ),
Data[StartTime] <= CurrTime,
Data[EndTime] >= CurrTime
)

Answer 3

In my example I put the data from your question into a table (insert > table) and named it tblData.
The axis-data are in table tblAxis, Quantity is calculated using the the SUMIFS-Formula which checks for Start and End-Time.
=SUMIFS(tblData[Quantity];tblData[StartTime];"<=" & [#Axis];tblData[EndTime];">" & [#Axis])

Answer 4

Thank you both.
Both solutions works!!
However for my limited knowledge, makes it easier for me to use ike solutions.