issues with Fortran function reshape - fortran

Question

I'm using codeblocks and gnu compiler to run Fortran code but I noticed something very strange.
Once I have an array (1,2,3,...,16) if I want to reshape to a 4x4 matrix I use the built-in reshape function, which should in theory use a column-major order for the numbers and so give (1 5 9 13; 2 6 10 14; 3 7 11 15; 4 8 12 16);
instead I get (1 2 3 4; 5 6 7 8; 9 10 11 12; 13 14 15 16).
This is a major inconsistency, I wonder if it is related to using codeblocks or what.
Anyone else with this problem and/or an idea about the reason and a solution.

Answer 1

I could not replicate the issue with Intel Fortran oneAPI HPC
and code for reference
program FortranConsole1
use, intrinsic :: iso_fortran_env
implicit none
interface show
procedure show_matrix_i, show_matrix_r, show_matrix_d
end interface
integer :: row(16), matrix(4,4)
real(real64) :: A(4,4)
row = [1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16]
matrix = reshape( row, [4, 4])
call show(matrix)
A = dble(matrix)
A = sqrt( matmul( transpose(A), A) )
call show(A, 8)
call show(A, 12)
call show(A, 16)
contains
subroutine show_matrix_i(A, w)
! Display the matrix 'A' in columns
! A : the array of integers
! w : the column width. Default = 5
integer, intent(in) :: A(:,:)
integer, intent(in), optional :: w
integer :: i,j,n,m, wt
character(len=16) :: fmt
if(present(w)) then
wt = w
else
wt = 5
end if
n = size(A,1)
m = size(A,2)
write( fmt, "(a,g0,a)") "(*(g",wt,".0))"
write( * , fmt ) ( (A(i,j),j=1,m), new_line("A"), i=1,n )
end subroutine
subroutine show_matrix_r(A, w)
! Display the matrix 'A' in columns
! A : the array of real numbers
! w : the column width. deafult = 12
! s : sig. figures w-5 (calculated)
real(real32), intent(in) :: A(:,:)
integer, intent(in), optional :: w
integer :: i,j,n,m,dg,wt
character(len=16) :: fmt
if(present(w)) then
wt = w
else
wt = 12
end if
dg = wt-5
n = size(A,1)
m = size(A,2)
write( fmt, "(a,g0,a,g0,a)") "(*(g",wt,".",dg,"))"
write( * , fmt ) ( (A(i,j),j=1,m), new_line("A"), i=1,n )
end subroutine
subroutine show_matrix_d(A,w)
! Display the matrix 'A' in columns
! A : the array of dble numbers
! w : the column width. default = 12
! Converts 'A' into single precision and calls `show_matrix_r`
real(real64), intent(in) :: A(:,:)
integer, intent(in), optional :: w
call show_matrix_r(real(A),w)
end subroutine
end program FortranConsole1
with results