Power BI Visual broken due to missing relationship - powerbi

Question

I'm trying to wrap my head around this conundrum and I'm drawing blanks.
I have Table Locals which is a list of locations each person is located in and during what dates:
Name Location Date Start Date End
Paul Las Vegas 2019/01/01 2020/12/31
Tom Los Angeles 2019/03/21 2020/02/14
Susan New York 2019/08/30 2020/06/28
Paul Chicago 2021/01/01 2021/12/31
and Table Contracts which is a table of contracts (each person can have more than one contract):
ID (unique) Person ID Type Date
1 345456345 Video 2019/02/05
2 867345315 Book 2019/05/14
3 345456345 Photo 2021/01/23
and Table Contacts which is a list of people and their contracts dates (each person can have more than one contract period):
Person ID (unique) Name
345456345 Paul
867345315 Tom
879316455 Susan
I need to determine the location of each contract.
So I established a relationship as follows:
Contracts/Person ID -> Contacts/Person ID
Contacts/Name -> Locals/Name
But from here, I am lost. My data visual (table containing Contract/Contract ID, Contacts/Name, Locals/Location) is broken because of the confusion in determining the location of Paul's contracts. The "Fix This" button is telling me that there is a missing relationship between the fields but autodetect isn't finding any relationships (obviously) and I don't know what other relationship I can create manually.
I know the secret is in determining whether the date on the contract falls within the Date Start and Date End of each location belonging to Paul but I don't know how to go about doing that.
Any ideas?

Answer 1

Ok, I took a closer look and I think I know what your problem is. You're trying to show in a visual, which contracts each person had in each location.
When you put Person's name and Location in a table, everything is fine. When you put Person's name and Contract ID everything is fine. The problem starts when you put it all together, as Power BI cannot determine, based on relationships, which contract was signed in which location.
To solve the issue, you would have to create a measure that would (for instance) count these contracts taking dates into account. Something like this:
#Contracts in Location =
var dateFrom = SELECTEDVALUE(Locals[Date Start])
var dateTo = SELECTEDVALUE(Locals[Date End])
return
COUNTROWS(FILTER(Contracts, Contracts[Date] >= dateFrom && Contracts[Date] <= dateTo))
If you place this measure in your visual, DAX will be able to figure out appropriate relationships based on row context and measure filters.
EDIT
Here's a measure that will also count contracts, when there is no person in the calculation context (by introducing it). I will assume that there is neither gap nor overlap for location dates for a single person.
#Contracts in Location =
SUMX (
Contacts,
CALCULATE (
COUNTROWS (
FILTER (
Contracts,
Contracts[Date] >= MIN ( Locals[Date Start] )
&& Contracts[Date] <= MAX ( Locals[Date End] )
)
)
)
)

Answer 2

It's possible to do it with your tables structure, but it would be better to change a bit your model.
That said, to obtain the following table visual, it's necessary to add also the contract ID set as "Don't summarize". This is needed to stop the table visual to try aggregate the rows, to allow the ContractLocation measure to work with the correct filter context, that must contain a single contract and a single contact.
and use a measure to set the relationship over the dates
ContractLocation =
VAR CurrentContractDate = SELECTEDVALUE( Contracts[Date] )
RETURN
IF(
NOT ISBLANK( CurrentContractDate ),
CALCULATE(
SELECTEDVALUE( Locals[Location] ),
FILTER( Locals, Locals[Date Start] <= CurrentContractDate && Locals[Date End] >= CurrentContractDate )
)
)
Edit: adding measure to also match location when there are no matching intervals
This measure uses the last known location. If the contract is before the first know location, then it uses the first known location. To be tested.
FuzzyContractLocation =
IF (
ISEMPTY ( Locals ) && NOT ISEMPTY(Contracts),
"Locale unknown",
VAR CurrentContractDate =
SELECTEDVALUE ( Contracts[Date] )
RETURN
IF (
NOT ISBLANK ( CurrentContractDate ),
VAR MinDateStart =
MIN ( Locals[Date Start] )
VAR MaxDateStart =
CALCULATE (
MAX ( Locals[Date Start] ),
Locals[Date Start] <= CurrentContractDate,
REMOVEFILTERS ( Locals[Date End] ),
REMOVEFILTERS ( Locals[Location] )
)
VAR DateStart =
IF ( ISBLANK ( MaxDateStart ), MinDateStart, MaxDateStart )
RETURN
CALCULATE ( SELECTEDVALUE ( Locals[Location] ), Locals[Date Start] = DateStart )
)
)
This would be better to be done in the data cleansing stage of the ETL, by building a consistent location table.