inserting an integer into a sorted list - list

Question

So my problem is this i have a predicate called insere_ordenado(El,Lst1,Lst2) in which El is a random integer, Lst1 is a list and Lst2 is the resulting list of adding El to Lst1.
The thing is i did this recursively but now i have to do this iteratively and the problem is when i want to add a number that is bigger or equal than the biggest number of the list it doesnt add anything.
Example:
?- insere_ordenado_ite(2,[1,2,3,6,9],L2).
L2 = [1, 2, 2, 3, 6, 9].
?- insere_ordenado_ite(5,[1,2,3,6,9],L2).
L2 = [1, 2, 3, 5, 6, 9].
?- insere_ordenado_ite(0,[1,2,3,6,9],L2).
L2 = [0, 1, 2, 3, 6, 9].
?- insere_ordenado_ite(9,[1,2,3,6,9],L2).
L2 = [1, 2, 3, 6, 9] .
?- insere_ordenado_ite(10,[1,2,3,6,9],L2).
L2 = [1, 2, 3, 6, 9] .
As you can see in the example that i want to add 9 or 10 its supposed to add 9 or 10 (depending on the example) at the end.
Program:
insere_ordenado_ite(El,L1,L2) :- insere_ordenado_ite(El,L1,L2,[]).
insere_ordenado_ite(El,[],L2,L2).
insere_ordenado_ite(El,[P|R],L2,AC) :- El >= P,
append(AC,[P],NAC),
insere_ordenado_ite(El,R,L2,NAC).
insere_ordenado_ite(El,[P|R],L2,AC) :- El < P,
append(AC,[El,P],NAC),
append(NAC,R,NNAC),
insere_ordenado_ite(El,[],L2,NNAC).
I think the problem is that something is missing from the stop condition, but I'm not sure what it is or how to do it exactly, honestly any help would be appreciated.

Answer 1

How about this, which I happen to have on hand.
It's as iterative as possible, there is nothing which happens after an insert_help/3, call. The tail of the difflist is constrained to a valid list eventually, and as variables are really global, this fact is immediately visible to whoever shares the variable, in this case insert/3.
insert(P,List,T) :-
DiffList=[-1|T]-T, % -1 is a guard, smaller than anything, removed later
insert_help(P,List,DiffList).
insert_help(P,[Px|R],H-T) :-
P>Px,!,
format("go right at ~q into ~q, difflist: ~q\n",[P,[Px|R],H-T]),
T=[Px|TT],
insert_help(P,R,H-TT).
insert_help(P,[P|R],H-T) :-
!,
format("~q exists in ~q, difflist: ~q\n",[P,[P|R],H-T]),
T=[P|R].
insert_help(P,[Px|R],H-T) :-
P<Px,!,
format("insert-before at ~q into ~q, difflist: ~q\n",[P,[Px|R],H-T]),
T=[P,Px|R].
insert_help(P,[],H-T) :-
!,
format("insert ~q at end, difflist: ~q\n",[P,H-T]),
T=[P].
:-begin_tests(inserting).
test(1) :- insert(10,[],R),R=[10].
test(2) :- insert(11,[2,3,5,7],R),R=[2,3,5,7,11].
test(3) :- insert(2,[3,5,7,11],R),R=[2,3,5,7,11].
test(4) :- insert(3,[2,3,5,7,11],R),R=[2,3,5,7,11].
test(5) :- insert(3,[2,5,7,11],R),R=[2,3,5,7,11].
test(6) :- insert(7,[2,3,5,11],R),R=[2,3,5,7,11].
test(7) :- insert(2,[],R),R=[2].
:-end_tests(inserting).
rt :- run_tests(inserting).
Addendum: Solving it with append/{2,3}
If you have append/3 (and append/2), you can just do:
insert_with_append(El,List,Out) :-
search(El,List,0,Result),
((Result >= 0) % -1 means entry exists
->
(length(Front,Result), % create list of fresh variables of length Result
append(Front,Back,List), % rip list apart into Front, Back
append([Front,[El],Back],Out)) % build result
;
Out = List % already exists in list
).
% search/4 looks for the insert position, counting the number of
% items in List that come before Element, and setting CounterOut
% to that value, once known. CounterOut is set to -1 if Element
% is already in the list.
% search(Element,List,CounterCur,CounterOut)
search(_,[],Counter,Counter) :- !.
search(E,[L|Ls],CounterCur,CounterOut) :-
L<E,!,
succ(CounterCur,CounterNext),
search(E,Ls,CounterNext,CounterOut).
search(E,[L|_],CounterCur,CounterCur) :-
E<L,!.
search(E,[E|_],_,-1).
:-begin_tests(insert_with_append).
test(1) :- insert_with_append(10,[],R),R=[10].
test(2) :- insert_with_append(11,[2,3,5,7],R),R=[2,3,5,7,11].
test(3) :- insert_with_append(2,[3,5,7,11],R),R=[2,3,5,7,11].
test(4) :- insert_with_append(3,[2,3,5,7,11],R),R=[2,3,5,7,11].
test(5) :- insert_with_append(3,[2,5,7,11],R),R=[2,3,5,7,11].
test(6) :- insert_with_append(7,[2,3,5,11],R),R=[2,3,5,7,11].
test(7) :- insert_with_append(2,[],R),R=[2].
:-end_tests(insert_with_append).
rt :- run_tests(insert_with_append).