SAS logic to populate 1 row based on another row - sas

Question

I have a SAS dataset like this:
Name MgrName Dept.
A B
B C
C D
X Y
I need to fill in the Dept. using a recursive logic. I know D is the head of 'Payroll', so I fill in:
Name MgrName Dept.
A B
B C
C D Payroll
X Y
But using some kind of recursion,everybody that is in D's reporting chain (A, B,C) also needs to be assigned 'Payroll'. How can I do that in SAS?

Answer 1

Here is a hash based approach in the context of a Proc DS2 program.
Each node (name) has only one parent (mgrname) so a hash can key with name and have mgrname as data. A loop over find method will seek the ancestral parent for a node or not find one.
Example (name is id and namemgr is pid):
data have;
input id $ pid $;datalines;
A B
B C
C D
F D
G F
H F
P H
Q H
R H
X Y
run;
proc ds2;
data want / overwrite=yes;
declare package hash links();
declare char _seek_pid;
declare char _seek_id;
declare char dept;
keep id pid dept;
* populate hash;
method init();
links.definekey('id');
links.definedata('pid');
links.dataset('{select pid, id from have {options locktable=share}}');
links.multidata('yes');
links.definedone();
end;
* seek ancestor from which value should be applied;
method apply(char rootid, char value, char id);
declare int limit;
limit = 0;
_seek_id = id;
do while (
links.find([_seek_id], [_seek_pid]) = 0 and
limit < 100 and
rootid ne _seek_pid
);
limit+1;
_seek_id = _seek_pid;
end;
if rootid = _seek_pid then dept = value;
end;
* apply some values to some nodes and children thereof;
method run();
set have (locktable=share);
apply ('D','payroll', id);
apply ('F','shadow$', id);
end;
enddata;
run;
quit;
%let syslast = want;

Answer 2

There is probably a smarter way, but here is a hash object approach
data have;
input Name $ MgrName $;
datalines;
A B
B C
C D
X Y
;
data want(drop=rc);
declare hash h1(dataset:'have');
h1.definekey('MgrName');
h1.definedata('Name');
h1.definedone();
declare hash h2();
h2.definekey('Name');
h2.definedone();
length Name $ 100 MgrName $ 100;
do rc=h1.find(key:'D') by 0 while (rc=0);
h2.replace();
rc=h1.find(key:Name);
end;
do until (lr);
set have end=lr;
Dept=ifc(h2.check()=0, 'Payroll', '');
output;
end;
run;