Count distinct id case when - sas

Question

I have table tb with these variables: id,year(it take values from 2007 to 2014 ,each year might be more than once) age_category(form 1 to 4)
I need to count distinct id for each year using different aga category.
I tried but not getting the result.
proc sql;
create table new as
select
COUNT( distinct id CASE WHEN year = 2007 and agecat=1 THEN id else 0 END) as yr_2007,
COUNT( distinct id CASE WHEN year = 2008 and agecat=1 THEN id else 0 END) as yr_2008,
COUNT( distinct id CASE WHEN year = 2009 and agecat=1 THEN id else 0 END) as yr_2009
from tb;

Answer 1

Your approach will need to use a construct such as
COUNT(distinct CASE when year=<year> and agecat=1 then id else . end) as year_<year>
Coding-wise this is probably the wrong approach, especially if you want the distinct counts for each agecat. You would need one expression for each year and agecat combination.
The transformation of the year values from being in a column to being in a column-name is a pivot (and data structure change) from data to metadata and leads to headaches. There are procedures such as PROC TABULATE and PROC REPORT for producing output that displays categorical data in columnar form. PROC TRANSPOSE can also be used to perform these pivots.
Sample code:
ods _all_ close;
ods html5 path='c:\temp' file='catcounts.html';
options nocenter nodate nonumber;
data have;
do id = 1 to 1000;
do year = 2007 to 2014;
if ranuni(123) < 0.75 then continue;
agecat = ceil(4*ranuni(123));
output;
end;
end;
run;
* ugly, expression pivot;
proc sql;
create table want(label="Unique ID count by year") as
select
count (distinct case when year=2007 and agecat=1 then id else . end) as yr_2007_age1_idcount,
count (distinct case when year=2008 and agecat=1 then id else . end) as yr_2007_age2_idcount,
count (distinct case when year=2009 and agecat=1 then id else . end) as yr_2007_age3_idcount
/* potentially many more */
from have;
* clean, categorical counts;
proc sql;
create table counts(label="Unique ID count by year and agecat") as
select
year, agecat, count(distinct id) as idCount
from have
group by year, agecat;
proc print noobs data=counts;
title "PRINT: Categorical counts results - output limited with where statement";
where year between 2010 and 2015 and agecat in (1,2);
run;
* pivot categorical, limited to agecat=1;
proc transpose data=counts out=counts_agecat1 prefix=year_;
id year;
var idCount;
where agecat=1;
quit;
proc print noobs data=counts_agecat1;
title "PRINT: ID Counts for agecat=1";
title2 "Pivot made with TRANSPOSE and limited with where statement";
run;
proc transpose data=counts out=counts_wide prefix=count_ delimiter=_;
id year agecat;
var idCount;
where agecat in (1,2);
quit;
proc print noobs data=counts_wide;
title "PRINT: ID counts for each year and agecat";
title2 "Pivot made with TRANSPOSE and ID year agecat and limited with where statement";
run;
proc tabulate data=counts;
title "Tabulate: Display the pre-computed categorical counts";
class year agecat;
var idCount;
table year='',agecat*idCount=''*sum=''*f=best12./nocellmerge;
run;
proc tabulate data=counts;
title "Tabulate: Display the pre-computed categorical counts";
class year agecat;
var idCount;
table agecat,year=''*idCount=''*sum=''*f=best12./nocellmerge;
run;
proc report data=counts;
title "Report: Display the pre-computed categorical counts";
column year agecat,idCount ;
define year / group;
define agecat / across;
run;
ods _all_ close;