Applying a template in XSLT and does not work - xslt

Question

I'm new to XSLT and i'm trying to apply a template to a certain node which is reached via nested for-each functions.
I have tried to simplify it and moved the apply-templates in only 1 for-each and there i got it to work.
This is my sample input xml:
<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<getPartMasterDataCompleteResponse >
<result>
<partMasterDataCompletes>
<partMasterDataComplete>
<part>A0001506450</part>
<version>11</version>
<partMasterData>
<language>german</language>
<part>A1234567890</part>
<releaseDateFrom>2018-09-06T08:52:18+02:00</releaseDateFrom>
<testTag>
<test></test>
<test></test>
<test></test>
</testTag>
</partMasterData>
</partMasterDataComplete>
</partMasterDataCompletes>
</result>
</getPartMasterDataCompleteResponse>
This is the xslt i'm using:
<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="getPartMasterDataCompleteResponse/result/partMasterDataCompletes">
<xsl:for-each select="partMasterDataComplete">
<Part>
<UserData>
<xsl:for-each select="partMasterData/*">
<xsl:if test="not(*)">
<xsl:choose>
<xsl:when test="local-name() = 'part'">
<xsl:apply-templates select="part"/>
</xsl:when>
<xsl:otherwise>
<UserValue>
<xsl:attribute name="title">
<xsl:value-of select="local-name()"/>
</xsl:attribute>
<xsl:attribute name="value">
<xsl:value-of select="current()"/>
</xsl:attribute>
</UserValue>
</xsl:otherwise>
</xsl:choose>
</xsl:if>
</xsl:for-each>
</UserData>
</Part>
</xsl:for-each>
</xsl:template>
<xsl:template match="part">
<UserValue title="PartNumber">
<xsl:attribute name="value">
<xsl:value-of select="current()"/>
</xsl:attribute>
</UserValue>
</xsl:template>
</xsl:stylesheet>
The result i get from Online-transformation tools is:
<Part>
<UserData>
<UserValue title="language" value="german"/>
<UserValue title="releaseDateFrom" value="2018-09-06T08:52:18+02:00"/>
</UserData>
</Part>
What i would expect is:
<Part>
<UserData>
<UserValue title="language" value="german"/>
<UserValue title="PartNumber" value="A0001506450"/>
<UserValue title="releaseDateFrom" value="2018-09-06T08:52:18+02:00"/>
</UserData>
</Part>
Any help is appreciated.
Thanks

Answer 1

When you do apply-templates, you are already positioned on a part element, so by doing <xsl:apply-templates select="part"/> you are actually looking for a child element called part on the current element. (i.e. it is actually the same as doing <xsl:apply-templates select="child::part"/>)
You want to apply the template to the current element, so do this instead:
<xsl:apply-templates select="."/>
Or, if you really wanted to make it explicit...
<xsl:apply-templates select="self::part"/>
As an aside, you can simplify your XSLT greatly, by better use of xsl:apply-templates and by using Attribute Value Templates to create attributes.
Try this XSLT
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes" />
<xsl:template match="getPartMasterDataCompleteResponse/result/partMasterDataCompletes">
<xsl:for-each select="partMasterDataComplete">
<Part>
<UserData>
<xsl:apply-templates select="partMasterData/*[not(*)]" />
</UserData>
</Part>
</xsl:for-each>
</xsl:template>
<xsl:template match="partMasterData/*">
<UserValue title="{local-name()}" value="{current()}" />
</xsl:template>
<xsl:template match="part">
<UserValue title="PartNumber" name="{current()}" />
</xsl:template>
</xsl:stylesheet>