How to output values from 2 different groups onto a single line? - xslt

Question

I have a file of employees that receive different types of earnings per pay period. Each employee can have from 1 to 3 different earning flag types (A, B, C) and these earnings can be for different dates.
For each employee I would like to sum the amounts together if the record has the same earning flag and date. If there is not an earning for say B then there should be a 0 in the B place.
I would like the output to be on the same line if possible to make readability and verification easier. This is the part I am having trouble with.
I have grouped by EmployeeID, EarningFlag, and Date. Then I summed the amounts for each grouping. The output though goes on separate lines and is a mess. I have no idea how to put a zero in place if there is no such earning flag on that date for the employee.
Example XML:
<Entry>
<EmployeeName>Bob Stevens</EmployeeName>
<EmployeeID>123</EmployeeID>
<EarningFlag>A</EarningFlag>
<Date>2019-04-01</Date>
<Amount>2031.54</Amount>
</Entry>
<Entry>
<EmployeeName>Bob Stevens</EmployeeName>
<EmployeeID>123</EmployeeID>
<EarningFlag>A</EarningFlag>
<Date>2019-04-01</Date>
<Amount>30.74</Amount>
</Entry>
<Entry>
<EmployeeName>Bob Stevens</EmployeeName>
<EmployeeID>123</EmployeeID>
<EarningFlag>B</EarningFlag>
<Date>2019-04-01</Date>
<Amount>1.63</Amount>
</Entry>
<Entry>
<EmployeeName>Samantha Philips</EmployeeName>
<EmployeeID>036</EmployeeID>
<EarningFlag>C</EarningFlag>
<Date>2019-04-01</Date>
<Amount>631.54</Amount>
</Entry>
<Entry>
<EmployeeName>Samantha Philips</EmployeeName>
<EmployeeID>036</EmployeeID>
<EarningFlag>C</EarningFlag>
<Date>2019-04-01</Date>
<Amount>3771.33</Amount>
</Entry>
<Entry>
<EmployeeName>Samantha Philips</EmployeeName>
<EmployeeID>036</EmployeeID>
<EarningFlag>A</EarningFlag>
<Date>2019-04-01</Date>
<Amount>631.54</Amount>
</Entry>
<Entry>
<EmployeeName>Samantha Philips</EmployeeName>
<EmployeeID>036</EmployeeID>
<EarningFlag>B</EarningFlag>
<Date>2019-03-07</Date>
<Amount>3771.33</Amount>
</Entry>
<xsl:for-each-group select="Entry" group-by="concat(EmployeeID,Date,EarningFlag)">
<xsl:sort select="current-grouping-key()"/>
<xsl:value-of select="EmployeeID"/>
<xsl:text>,</xsl:text>
<xsl:value-of select="EmployeeName"/>
<xsl:text>,</xsl:text>
<xsl:value-of select="Date"/>
<xsl:text>,</xsl:text>
<xsl:if test="EarningFlag='A'">
<xsl:value-of select="sum(current-group()/Amount)"/>
</xsl:if>
<xsl:text>,</xsl:text>
<xsl:if test="EarningFlag='B'">
<xsl:value-of select="sum(current-group()/Amount)"/>
</xsl:if>
<xsl:text>,</xsl:text>
<xsl:if test="EarningFlag='C'">
<xsl:value-of select="sum(current-group()/Amount)"/>
</xsl:if>
</xsl:for-each-group>
My actual results are:
123,Bob Stevens,2019-04-04,2062.28123,Bob Stevens,2019-04-04,1.63,
036,Samantha Philips,2019-03-07,3771.33,
036,Samantha Philips,2019-04-01,631.54,036,Samantha Philips,2019-04-01,3771.33
The expected output would be in the order of Employee ID, Employee Name, Date, A, B, C.
123,Bob Stevens,2019-04-01,2062.28,1.63,0
036,Samantha Philips,2019-03-07,0,3771.33,0
036,Samantha Philips,2019-04-01,631.54,0,3771.33
Is this even possible???
Thank you for any help.

Answer 1

Following on from the answer from #michael.hor257k, you can also write
<xsl:for-each-group select="Entry" group-by="concat(EmployeeID,Date)">
<xsl:sort select="EmployeeID"/>
<xsl:sort select="Date"/>
<xsl:value-of select="EmployeeID, EmployeeName, Date,
sum(current-group([EarningFlag='A']/Amount),
sum(current-group()[EarningFlag='B']/Amount,
sum(current-group()[EarningFlag='C']/Amount"
separator=","/>
<xsl:text>
</xsl:text>
</xsl:for-each-group>

Answer 2

I guess you want to do:
<xsl:for-each-group select="Entry" group-by="concat(EmployeeID,Date)">
<xsl:sort select="EmployeeID"/>
<xsl:sort select="Date"/>
<xsl:value-of select="EmployeeID"/>
<xsl:text>,</xsl:text>
<xsl:value-of select="EmployeeName"/>
<xsl:text>,</xsl:text>
<xsl:value-of select="Date"/>
<xsl:text>,</xsl:text>
<xsl:value-of select="sum(current-group()[EarningFlag='A']/Amount)"/>
<xsl:text>,</xsl:text>
<xsl:value-of select="sum(current-group()[EarningFlag='B']/Amount)"/>
<xsl:text>,</xsl:text>
<xsl:value-of select="sum(current-group()[EarningFlag='C']/Amount)"/>
<xsl:text>
</xsl:text>
</xsl:for-each-group>