building an XSLT string using variable in a foreach loop - xslt

Question

The problem I'm facing perhaps simple for others, but being a beginner XSL - I'm yet to find a proper solution. What I want to do is build a string by concatenating the results of variables define in for-each loop.
Sorry it should be this:
<linked-hash-map>
<entry>
<string>properties</string>
<list>
<linked-hash-map>
<entry>
<string>property_id</string>
<int>123</int>
</entry>
<entry>
<string>type</string>
<string>H</string>
</entry>
<entry>
<string>status</string>
<string>CURRENT</string>
</entry>
<entry>
<string>description</string>
<string>Test</string>
</entry>
<entry>
<string>lots</string>
<list>
<linked-hash-map>
<entry>
<string>lot_id</string>
<int>123</int>
</entry>
<entry>
<string>lot_number</string>
<int>11</int>
</entry>
<entry>
<string>plan_number</string>
<int>100</int>
</entry>
<entry>
<string>plan_type</string>
<string>CC</string>
</entry>
<entry>
<string>plan_id</string>
<int>1</int>
</entry>
</linked-hash-map>
</list>
</entry>
</linked-hash-map>
</list>
</entry>
Desired output: SP - 31 - 108661
So basically I want to concatenate the plan_type, lot_number, and plan_number together into one string.
I've tried this:
<xsl:for-each select="linked-hash-map/entry/linked-hash-map/entry/list/linked-hash-map/entry" >
<xsl:choose>
<!-- LOT NUMBER -->
<xsl:when test="string[1] = 'lot_number'">
<xsl:variable name="lot_number" select="int" />
</xsl:when>
<!-- PLAN NUMBER -->
<xsl:when test="string[1] = 'plan_number'">
<xsl:variable name="plan_number" select="int" />
</xsl:when>
<!-- PLAN TYPE -->
<xsl:when test="string[1] = 'plan_type'">
<xsl:variable name="plan_type" select="string[2]" />
</xsl:when>
</xsl:choose>
</xsl:for-each>
<!-- LOT DETAIL -->
// concatenate string in here.
<xsl:value-of select="concat($plan_type, '-', $lot_number, '-', $plan_number)" />
But it doesn't work because of the variable being out of scope.
How can I achieve that desired output?
Thank you.

Answer 1

To change as little as possible, try the following XSLT-1.0 code:
<xsl:template match="linked-hash-map">
<xsl:variable name="plan_type" select="entry[string='plan_type']/string[2]/text()" />
<xsl:variable name="lot_number" select="entry[string='lot_number']/int/text()" />
<xsl:variable name="plan_number" select="entry[string='plan_number']/int/text()" />
<xsl:value-of select="concat($plan_type, ' - ', $lot_number, ' - ', $plan_number)" />
</xsl:template>
Its result is:
SP - 31 - 108661

Answer 2

Note that variables are local in scope to the block in which they are declared, so the each variable in this case would only be accessible within the xsl:when
But you don't need xsl:for-each or variables here. You can just do something like this (assuming you were in a template matching linked-hash-map
<xsl:value-of select="concat(entry[string[1]='plan_type']/string[2], '-', entry[string[1]='lot_number']/int, '-', entry[string[1]='plan_number']/int)" />
Or maybe, to make it a bit more readable, separate out the lines
<xsl:value-of select="entry[string[1]='plan_type']/string[2]" />
<xsl:text>-</xsl:text>
<xsl:value-of select="entry[string[1]='lot_number']/int" />
<xsl:text>-</xsl:text>
<xsl:value-of select="entry[string[1]='plan_number']/int" />
See http://xsltfiddle.liberty-development.net/eiZQaGs/2

Answer 3

We don't have an XSLT version number on the question, so I wondered what I would write in 3.0. Perhaps:
<xsl:value-of select="for $n in ('plan_type', 'lot_number', 'plan_number')
return entry[string[1]=$n]/*[2]"
separator=" - "/>