How to match CR CR LF newline pattern [duplicate] - regex

Question

This question already has answers here:
Does awk CR LF handling break on cygwin?
(2 answers)
Closed 4 years ago.
In Windows 10 environment I have to check how many CSV files (separator is ";") in a directory have this odd newline pattern: CR CR LF (or \r\r\n if you prefer).
However, I can match \r\r neither with grep nor with awk. On awk I've also tried to change RS to be ; and FS a not-used character (#), but apparently awk matches single CR, not CR CR. So awk in Windows sees CR CR LF as CR LF and FNR output a number of records equal to any other "normal end-line" file.
Strange thing is that with Notepad++ I can clearly see CR CR LF (causing an extra line break, as e.g. in Excel) and with built-in regex finder, search for \r\r\n match all the lines. Is it not possible to force awk to act on a raw text file without removing some CR?
The file is like this (I've simplified a little): 5 lines with 4 x fields separated by ; and a the end of each line CRCRLF. Opening with Notepad++ (and Excel) I see 10 lines.
I hoped that the following GNU awk script would return 16 5
BEGIN {RS = ";";FS = "#"; linecount = 0}
/\r\r/ {linecount = linecount + 1}
END {print FNR, linecount}
However, it returns 16 0. If I search to match /\r/ instead, I obtain 16 5.
So basically I'm afraid that Windows CMD shell is stripping out one of the two consecutive CR (or to say it better, is replacing a CR LF pair with LF) before passing stream to gawk, I was wondering if it is possible to avoid this, because I want to use gawk to detect how many files have this weird CR CR LF newline.
I believe a very similar question has been posted here:
In Perl, how to match two consecutive Carriage Returns?

Answer 1

After realizing there is a duplicate (thanks #tripleee):
Under MS-Windows, gawk (and many other text programs) silently translates end-of-line \r\n to \n on input and \n to \r\n on output. A special BINMODE variable (c.e.) allows control over these translations and is interpreted as follows:
If BINMODE is "r" or one, then binary mode is set on read (i.e., no translations on reads).
If BINMODE is "w" or two, then binary mode is set on write (i.e., no translations on writes).
If BINMODE is "rw" or "wr" or three, binary mode is set for both read and write.
BINMODE=non-null-string is the same as BINMODE=3 (i.e., no translations on reads or writes). However, gawk issues a warning message if the string is not one of "rw" or "wr".
source: https://www.gnu.org/software/gawk/manual/gawk.html#PC-Using
To keep awk in its original POSIX-style, you should use BINMODE=3. Using awk (or any unmodified version), you should easily be able to do it by checking if the record ends with \r\r. This is because awk defaultly0 splits a file in records using RS="\n". As GOW is using GNU awk, you have the following options:
count files:
awk '/\r\r$/{f++; nextfile} END {print f,"files match"}' BINMODE=3 *.csv
count files and print filename:
awk '/\r\r$/{f++; print FILENAME; nextfile} END {print f,"files match"}' BINMODE=3 *.csv
count files, print filename and lines:
awk '(FNR==1){if (c) {print fname, c; f++}; c=0; fname=FILENAME}
/\r\r$/{c++}
END { print f,"files match" }' BINMODE=3 *.csv
note: remove BINMODE=3 on any POSIX system.

Answer 2

You can try GNU grep's -z and -P switch, try this:
grep -zcP "\r\r\n" *.csv | awk -F: "$2{c++}END{print c}"
So I created a file like you said by this:
awk 'BEGIN{ORS="\r\r\n"; OFS=";"; for(i=1;i<11;i++)print "aa","bb","cc",i>"strange.csv"}'
And I can search \r\r\n in the csv files like this:
> grep -zcP "\r\r\n" *.csv
file1.csv:0
file2.csv:0
file3.csv:0
file_a.csv:0
file_b.csv:0
results.csv:0
strange.csv:1
And combine it with awk:
awk -F: "$2{c++}END{print c}"
to get the count:
> grep -zcP "\r\r\n" *.csv | awk -F: "$2{c++}END{print c}"
1
OR, just use awk alone:
> awk 'BEGIN{RS="";}/\r\r\n/{c++;nexfile}END{print c}' *.csv
1
So both above grep and awk examples, read whole file instead of dealing with each line every turn.