XSLT 2.0 reformatting dates - xslt

Question

Say I have a date that I composed in the form "2018-03-00". I want this to be "00-MAR-18". What functions, in XSLT 2.0, if any, are available for this.
I was looking for month(3) = MAR. And I was going to compose the additional fields myself.

Answer 1

Take a look at format-date().
With the day being "00" your date isn't castable as an xs:date. If you really have "00", you won't be able to use format-date().
If your dates are castable as xs:date's, here's an example...
XML Input
<test>2018-03-01</test>
XSLT 2.0
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema">
<xsl:output indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="/*">
<xsl:copy>
<xsl:value-of select="format-date(., '[D01]-[MN,*-3]-[Y01]')"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
Output
<test>01-MAR-18</test>
Fiddle: http://xsltfiddle.liberty-development.net/3NzcBtj
EDIT
Since your dates aren't really dates, you could create your own function...
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:so="stackoverflow.test">
<xsl:output indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:function name="so:format_month">
<xsl:param name="date_string"/>
<xsl:variable name="months" select="(
'JAN','FEB','MAR',
'APR','MAY','JUN',
'JUL','AUG','SEP',
'OCT','NOV','DEC')"/>
<xsl:variable name="date_tokens" select="tokenize($date_string,'-')"/>
<xsl:value-of select="($date_tokens[3],
$months[number($date_tokens[2])],
substring($date_tokens[1],3,2))" separator="-"/>
</xsl:function>
<xsl:template match="/*">
<xsl:copy>
<xsl:value-of select="so:format_month(.)"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
Fiddle: http://xsltfiddle.liberty-development.net/3NzcBtj/2