SAS if-else if not working - sas

Question

combd dataset
SAS is checking the first if statement and ignoring the others for some reason. For a couple obs "class" = 1 and for all the others it is blank. What do I do? I do need the parentheses to group those "or" statements right. Attached is the combd dataset. Just noticed for obs where SAS has class=1 it is wrong!
data clustered;
set combd;
if ((393821 ge avpm le 450041) or (337601 ge avpm le 393821) or (225161
ge avpm le 281381)) and (.8768 ge fsp le 1) then class='1';
else if ((112720 ge avpm le 168940) or (56500 ge avpm le 112720) or
(280.06 ge avpm le 56500)) and (.8768 ge fsp le 1) then class='2';
else if (280.06 ge avpm le 56500) and ((.507 ge fsp le .6303) or
(.3838 ge fsp le .507) or (.2606 ge fsp le .3838)) then class='3';
else if (280.06 ge avpm le 56500) and ((.1373 ge fsp le .2606) or
(.0141 ge fsp le .1373)) then class='4';
else if (280.06 ge avpm le 56500) and (.8768 ge fsp le 1) then
class='5';
else if (280.06 ge avpm le 56500) and ((.8768 ge fsp le 1) or
(.7535 ge fsp le .8768) or (.6303 ge fsp le .7535)) then
class='6';
run;

Answer 1

This is wrong:
(393821 ge avpm le 450041)
Any number less than 393821 will also be less than 450041.
You want this:
(393821 le avpm le 450041)
393821 less than AVPM less than 450041, meaning, avpm is between 393821 and 450041. Do that for all of your data.
Second: don't write your code this way. It's hard to read and difficult to debug. Instead use a data driven code method.
You have really a relationship here, right? [some AVPM values] and [some FSP values] -> [some CLASS value]
So let's make a table:
data class;
input class avpm_min avpm_max fsp_min fsp_max;
datalines;
1 393821 450041 .8768 1
1 337601 393821 .8768 1
1 225161 281381 .8768 1
2 112720 168940 .8768 1
2 056500 112720 .8768 1
2 280.06 056500 .8768 1
3 280.06 056500 .5070 .6303
3 280.06 056500 .3838 .5070
3 280.06 056500 .2606 .3838
6 280.06 056500 .6303 .7535
6 280.06 056500 .7535 .8768
;;;; /*more datalines of course */
run;
And then let's use PROC SQL to join this to the main table.
data your_data;
input avpm fsp;
obs=_n_;
datalines;
13026.14 .81888
1810.57 .84959
3859.84 .85593
3290.61 .57513
10704.72 .71414
;;;;
run;
proc sql;
select d.obs, d.avpm, d.fsp, c.class from
your_data d
left join class c
on c.avpm_min le d.avpm le c.avpm_max
and c.fsp_min le d.fsp le c.fsp_max
order by d.obs
;
quit;
There you go.
I'd also note that your IF/ELSE combinations don't really make sense for 4/5/6. 5 is impossible (it's entirely subsumed by 2) and part of 6 is also.