How do I remove duplicates from an array of structs in Coldfusion - coldfusion

Question

I want to reduce this, note here I have a field which I know to mark as a unique identifier:
To this:

Answer 1

I did it by writing this function (basically copying the keys into a struct if it doesn't exist and adding it to the final array):
<cffunction name="RemoveDuplicatesFromObjectArray">
<cfargument name="objs" type="array">
<cfargument name="key" type="string">
<cfscript>
var keys ={};
var result = [];
for (var obj in arguments.objs)
{
if (not StructKeyExists(keys, obj[arguments.key]))
{
ArrayAppend(result, obj);
keys[obj[arguments.key]] = true;
}
}
</cfscript>
<cfreturn result>
</cffunction>
and calling it like this:
<cfset arr = [{
"EXPENSEREPORTID": 129591,
"EXPENSELINEITEMID": 602684,
"DOLLARSBEFORE": 8.1000000000,
"DOLLARSAFTER": 5.4000000000
}, {
"EXPENSEREPORTID": 129591,
"EXPENSELINEITEMID": 602684,
"DOLLARSBEFORE": 8.1000000000,
"DOLLARSAFTER": 5.4000000000
}]>
<Cfdump var="#RemoveDuplicatesFromObjectArray(arr,'EXPENSEREPORTID')#">

Answer 2

Just for fun since you are on CF11+, I thought I would do it with ArrayFilter() since you might interested in seeing an alternative, but your answer is great (I see Leigh fixed the couple of issues). You build up a struct to match on keys and amend a return array at the same time.
Using a struct as an index will far outperform other methods that might use ArrayFind() over larger arrays. What's even better is to actually build up a struct over an array from the beginning. In this manner, you don't have to worry about uniqueness. If order is important, LinkedHashMaps are available.
Here is the example:
http://trycf.com/gist/df2fad58219163b7b64c9523b8383921/acf11
<cfscript>
data = [
{
dollarsafter : 5.4
, dollarsbefore : 8.1
, expenselineitemid : 602684
, expensereportid : 129591
}
,{
dollarsafter : 5.4
, dollarsbefore : 8.1
, expenselineitemid : 602684
, expensereportid : 129593
}
,{
dollarsafter : 5.4
, dollarsbefore : 8.1
, expenselineitemid : 602684
, expensereportid : 129591
}
];
function doFilter( data ){
var index = {};
return data.filter( function( item ){
return ! itemFoundInIndexByKey( item, index, item['expensereportid'] );
});
}
function itemFoundInIndexByKey( item, index, key ){
var foundIt = index.keyExists( key );
if( ! foundIt ){
index[ key ] = '';
}
return foundIt;
}
writeDump( doFilter( data ) );
</cfscript>
Bonus example concise code (Not using reusable logic for the filter):
http://trycf.com/gist/e3ae76877bdc0809f02ee3333d51f8ae/acf11?theme=monokai
<cfscript>
data = [
{
dollarsafter : 5.4
, dollarsbefore : 8.1
, expenselineitemid : 602684
, expensereportid : 129591
}
,{
dollarsafter : 5.4
, dollarsbefore : 8.1
, expenselineitemid : 602684
, expensereportid : 129593
}
,{
dollarsafter : 5.4
, dollarsbefore : 8.1
, expenselineitemid : 602684
, expensereportid : 129591
}
];
function filterDuplicateObjectArrayByKey( required array data, required string key, index = {} ){
return data.filter( function( item ){
if( ! index.keyExists( item[ key ] ) ){
index[ item[ key ] ] = '';
return true;
}
return false;
});
}
writeDump( filterDuplicateObjectArrayByKey( data, 'expensereportid' ) );
</cfscript>