How to add two columns with specified condition in SAS? - sas

Question

How to add two columns with specified condition in SAS?
Here I want to add the column data that is specified in first 2 columns.
data data1;
set data;
column1 = x;
column2 = y;
total = column1 + column2;
run;
input
x y a b c d e
-- -- -- -- -- -- --
a c 1 45 32 7 45
b a 22 45 55 33 55
d e 56 78 66 44 12
c d 33 45 44 56 77
Output
x y a b c d e Output
-- -- -- -- -- -- -- ------
a c 1 45 32 7 45 33
b a 22 45 55 33 55 67
d e 56 78 66 44 12 56
c d 33 45 44 56 77 100

Answer 1

Here's a simpler solution. Create an array of the possible numbers to add, loop through them and check if the variable name is the same as the value in x or y, using the vname function.
data have;
input x $ y $ a b c d e;
datalines;
a c 1 45 32 7 45
b a 22 45 55 33 55
d e 56 78 66 44 12
c d 33 45 44 56 77
;
run;
data want;
set have;
array vars{*} a--e;
output=0;
do i = 1 to dim(vars);
if x=vname(vars{i}) then output+vars{i};
if y=vname(vars{i}) then output+vars{i};
end;
drop i;
run;

Answer 2

I'm sure there's a cleaner way of doing this, but this works:
data data;
input
x $ y $ a b c d e;
datalines;
a c 1 45 32 7 45
b a 22 45 55 33 55
d e 56 78 66 44 12
c d 33 45 44 56 77
;
run;
data data1;
set data;
count = _n_;
run;
proc sql noprint;
select count into: countlist
separated by " " from data1;
quit;
proc sql noprint;
select x into: xlist
separated by " " from data1;
quit;
proc sql noprint;
select y into: ylist
separated by " " from data1;
quit;
%macro add;
data data2 (drop = count);
set data1;
%do i = 1 %to %sysfunc(countw(&countlist.));
%let this_x = %scan(&xlist., &i.);
%let this_y = %scan(&ylist., &i.);
if &i. = count then total = &this_x. + &this_y.;
%end;
run;
%mend add;
%add;